program ringBuffSave2
option +r;
option -c;

%% #include <stdio.h>
%% #include <string.h>
%% #include <epicsTime.h>
%% static void getTimestampString(char *ts_string, int num);
%% static void save_file(char *dir, char *file_name, double rate, int post_trig_delay, int length, int adc0[], int adc1[], int adc2[], int adc3[]);

double rate;
int    post_trig_delay;
int    adc0[1024], adc1[1024], adc2[1024], adc3[1024];

int    log;

char   *dir_name;
char   *file_prefix;

assign rate       to "{NAME}:LOGRATE";           monitor rate;
assign post_trig_delay to "{NAME}:POSTTRIGDLY";  monitor post_trig_delay;
assign adc0       to "{NAME}:RBUF:ADC0";         monitor adc0;
assign adc1       to "{NAME}:RBUF:ADC1";         monitor adc1;
assign adc2       to "{NAME}:RBUF:ADC2";         monitor adc2;
assign adc3       to "{NAME}:RBUF:ADC3";         monitor adc3;
assign log        to "{NAME}:STOPLOG";           monitor log; 


%{
    static void getTimestampString(char *ts_string, int num)
    {
        epicsTimeStamp t;
        epicsTimeGetCurrent(&t);
        epicsTimeToStrftime(ts_string, num, "%Y%m%d_%H%M%S", &t);
    }
    
    static void save_file(char *dir, char *file_name, double rate, int post_trig_delay, int length, int adc0[], int adc1[], int adc2[], int adc3[])
    {
        char ts_string[64];
        char fname[512];
        FILE *file;
        int  i;
        
        getTimestampString(ts_string, 64);
        sprintf(fname, "%s/%s_%s.csv", dir, file_name, ts_string);
                
        file = fopen(fname, "w");
        if(!file) { 
            printf("could not open file (%s)\n", fname);
            return;
        }
        
        fprintf(file, "rate, %fMHz\n", rate);
        fprintf(file, "post_trig_delay, %d\n", post_trig_delay); 
        fprintf(file, "length, %d\n", length);
        
        
        fprintf(file, "adc0");
        for(i=0; i<1024; i++) fprintf(file, ", %d", adc0[i]);
        fprintf(file, "\n");
        
        fprintf(file, "adc1");
        for(i=0; i<1024; i++) fprintf(file, ", %d", adc1[i]);
        fprintf(file, "\n");
     
        fprintf(file, "adc2");
        for(i=0; i<1024; i++) fprintf(file, ", %d", adc2[i]);
        fprintf(file, "\n");
        
        fprintf(file, "adc3");
        for(i=0; i<1024; i++) fprintf(file, ", %d", adc3[i]);
        fprintf(file, "\n");   
        
        fclose(file);
     
        
    }
}%

ss ringBuffSave 
{
    state init
    {
        when(1) {
            dir_name    = macValueGet("DIR")? macValueGet("DIR"):"/tmp";
            file_prefix = macValueGet("FILE")? macValueGet("FILE"): "waveform_ringbuf"; 
        } state release
    }
    
    state release 
    {
        when(log) {
            /* nothing to do */
        } state push
    }
    
    state push
    {
        when(!log) {
            /* save file */
            %% save_file (pVar->dir_name, pVar->file_prefix, pVar->rate, pVar->post_trig_delay, 1024, pVar->adc0, pVar->adc1, pVar->adc2, pVar->adc3);
            epicsThreadSleep(2.);
            
        } state release
    }
    
}
