! *** OPTICS=AD_ACCEL_HE-28APR21 ***

! LCLS2sc injector #2: from CATHODELEI to merge with original LCLS-II injector
!   (diagnostic line, spectrometer line, and dump line in DIAGI.xsif))

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 19-APR-2021, M. Woodley
!  * remove gun bucking coil per C. Mayes
!  * set L, DELTAE, and PHI0 for bunchers per C. Mayes
!  * add thin-lens normal and skew quadrupoles to GUNLEI solenoids
! 15-APR-2021, M. Woodley
!  * locations of DLI wall and stoppers per R. Coy
!  * add initial complement of devices to GUNLEI (in made-up locations)
! 09-APR-2021, Y. Nosochkov
!  * include LEI TCAV between Q0D03 and Q0D04 (location per R. Coy)
! 07-APR-2021, M. Woodley
!  * add simplified gun line per F. Ji
! 02-APR-2021, Y. Nosochkov
!  * increase LEI dogleg angle to 35 degrees (Tor)
!  * reduce spacing between dogleg magnets
! 26-MAR-2021, Y. Nosochkov
!  * reduce LD0D14 from 6.1 to 3.827898, set length of D0D02 and D0D03 to 1.3 m
!  * rematch Q0D01-04
! 23-MAR-2021, Y. Nosochkov
!  * reduce distance between Q0D01 and Q0D02 to 0.427898 m
!  * reduce LD0D14 to 6.1 m, adjust quad positions and rematch
! 15-MAR-2021, Y. Nosochkov
!  * reduce LD0D14 by 0.1 m; rematch quads u/s of dogleg
! 13-MAR-2021, Y. Nosochkov
!  * optimize positions and strengths of matching quads Q0D01-04
!    to minimize length of matching section u/s of the dogleg
! 09-MAR-2021, M. Woodley
!  * add matching between CM00 and dogleg
! 05-MAR-2021, Y. Nosochkov
!  * initial dogleg design with 6 m horizontal displacement
!  * cancellation of 2nd order dispersion
!  * free ~5 m space at center of the dogleg for shielding
! ------------------------------------------------------------------------------

! ==============================================================================
! LCAV
! ------------------------------------------------------------------------------

! LCLS-II buncher cavity (use C. Mayes cavity effective length)

  LBUN1LEI :=  0.358133                  !m (0.21876)
  RBUN1LEI :=  0.0517/2                  !m
  GBUN1LEI :=  0.35108825924014/0.358133 !MV/m
  PBUN1LEI := -0.11900011084944          !rad/2pi

  BUN1LEI : LCAV, TYPE="LCLS-II", FREQ=1300, L=LBUN1LEI/2, APER=RBUN1LEI, &
                  DELTAE=GBUN1LEI*LBUN1LEI/2, PHI0=PBUN1LEI

! 9-cell SRF cavity buncher (use LCLS-II cavity effective length)

  LBUN2LEI :=  1.037743              !m
  RBUN2LEI := 70e-3/2                !m
  GBUN2LEI :=  8.8578630538/1.037743 !MV/m
  PBUN2LEI := -0.16153574142949      !rad/2pi

  BUN2LEI : LCAV, TYPE="9-cell SRF", FREQ=1300, L=LBUN2LEI/2, APER=RBUN2LEI, &
                  DELTAE=GBUN2LEI*LBUN2LEI/2, PHI0=PBUN2LEI

! ==============================================================================
! TCAV
! ------------------------------------------------------------------------------

  TCXDGI : LCAV, TYPE="@2,TRANS_XDEF", FREQ=2856, L=0.6680236/2 !X-deflector (split)

! ==============================================================================
! SBEN
! ------------------------------------------------------------------------------

  ADLI  := 35*RADDEG !injection line angle (rad)
  ZBDLI := 0.2032    !5D7.1 "Z" length (m)
  GBDLI := 30.E-3    !5D7.1 full gap height (m)
  FBDLI := 0.45      !5D7.1 measured FINT / FINTX

  ABDLI := ADLI/2                       !full bend angle (rad)
  LBDLI := ZBDLI*ABDLI/(2*SIN(ABDLI/2)) !full bend path length (m)
  EBDLI := ABDLI/2                      !bend edge angles

  BXDLI1a : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE= ABDLI/2, E1= EBDLI, FINT=FBDLI, FINTX=0
  BXDLI1b : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE= ABDLI/2, E2= EBDLI, FINT=0, FINTX=FBDLI
  BXDLI2a : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE= ABDLI/2, E1= EBDLI, FINT=FBDLI, FINTX=0
  BXDLI2b : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE= ABDLI/2, E2= EBDLI, FINT=0, FINTX=FBDLI

  BXDLI3a : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE=-ABDLI/2, E1=-EBDLI, FINT=FBDLI, FINTX=0
  BXDLI3b : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE=-ABDLI/2, E2=-EBDLI, FINT=0, FINTX=FBDLI
  BXDLI4a : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE=-ABDLI/2, E1=-EBDLI, FINT=FBDLI, FINTX=0
  BXDLI4b : SBEN, TYPE="1.182D6.82T", L=LBDLI/2, HGAP=GBDLI/2, &
                  ANGLE=-ABDLI/2, E2=-EBDLI, FINT=0, FINTX=FBDLI

! define unsplit SBENs for BMAD ... not used by MAD

  BXDLI1 : SBEN, TYPE="1.182D6.82T", L=LBDLI, HGAP=GBDLI/2, ANGLE= ABDLI, &
                 E1= EBDLI, FINT=FBDLI, E2= EBDLI, FINTX=FBDLI
  BXDLI2 : SBEN, TYPE="1.182D6.82T", L=LBDLI, HGAP=GBDLI/2, ANGLE= ABDLI, &
                 E1= EBDLI, FINT=FBDLI, E2= EBDLI, FINTX=FBDLI
  BXDLI3 : SBEN, TYPE="1.182D6.82T", L=LBDLI, HGAP=GBDLI/2, ANGLE=-ABDLI, &
                 E1=-EBDLI, FINT=FBDLI, E2=-EBDLI, FINTX=FBDLI
  BXDLI4 : SBEN, TYPE="1.182D6.82T", L=LBDLI, HGAP=GBDLI/2, ANGLE=-ABDLI, &
                 E1=-EBDLI, FINT=FBDLI, E2=-EBDLI, FINTX=FBDLI

! ==============================================================================
! QUAD
! ------------------------------------------------------------------------------

! correction coils co-wound on GUNLEIsolenoids

  CQ01LEI : MULT, TYPE="solenoid trim", APER=0.091/2,  K1L=0
  SQ01LEI : MULT, TYPE="solenoid trim", APER=0.091/2,  K1L=0, T1
  CQ02LEI : MULT, TYPE="solenoid trim", APER=0.0475/2, K1L=0
  SQ02LEI : MULT, TYPE="solenoid trim", APER=0.0475/2, K1L=0, T1
  CQ03LEI : MULT, TYPE="solenoid trim", APER=0.0475/2, K1L=0
  SQ03LEI : MULT, TYPE="solenoid trim", APER=0.0475/2, K1L=0, T1

! CM00 to dogleg

  KQ0D01 :=  5.719105291692 
  KQ0D02 := -6.099340907527 
  KQ0D03 :=  0.168 
  KQ0D04 :=  2.836161755439

  Q0D01 : QUAD, TYPE="2Q4", L=LQM/2, APER=rQM, K1=KQ0D01
  Q0D02 : QUAD, TYPE="2Q4", L=LQM/2, APER=rQM, K1=KQ0D02
  Q0D03 : QUAD, TYPE="2Q4", L=LQM/2, APER=rQM, K1=KQ0D03
  Q0D04 : QUAD, TYPE="2Q4", L=LQM/2, APER=rQM, K1=KQ0D04

! dogleg

  KQDLI1 :=  20.250131799744 !fixed to cancel dispersion
  KQDLI2 := -7.203108132532
  KQDLI3 :=  12.956232323948
  KQDLI4 := -4.891851114058
  KQDLI5 :=  KQDLI4
  KQDLI6 :=  KQDLI3
  KQDLI7 :=  KQDLI2
  KQDLI8 :=  KQDLI1

  QDLI1 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI1, APER=rQx
  QDLI2 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI2, APER=rQx
  QDLI3 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI3, APER=rQx
  QDLI4 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI4, APER=rQx
  QDLI5 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI5, APER=rQx
  QDLI6 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI6, APER=rQx
  QDLI7 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI7, APER=rQx
  QDLI8 : QUAD, TYPE="1.26Q3.5", L=LQx/2, K1=KQDLI8, APER=rQx

! ==============================================================================
! SOLE
! ------------------------------------------------------------------------------

  BrhoLEI := Cb*SQRT(E0^2-mc2^2) !kG-m (non-relativistic)

! Danfysik HTS solenoid

  LSOL1LEI := 0.134 !m
  RSOL1LEI := 0.091/2 !m
  BSOL1LEI := 0 !T
  KSOL1LEI := (10*BSOL1LEI)/BrhoLEI !1/m

  SOL1LEI : SOLE, TYPE="Danfysik HTS", L=LSOL1LEI/2, APER=RSOL1LEI, &
                  KS=KSOL1LEI

! APEX solenoids

  LSOL2LEI := 0.135 !m
  RSOL2LEI := 0.0475/2 !m
  BSOL2LEI := 0 !T
  KSOL2LEI := (10*BSOL2)/BrhoLEI !1/m

  LSOL3LEI := 0.135 !m
  RSOL3LEI := 0.0475/2 !m
  BSOL3LEI := 0 !T
  KSOL3LEI := (10*BSOL2)/BrhoLEI !1/m

  SOL2LEI : SOLE, TYPE="APEX", L=LSOL2LEI/2, APER=RSOL2LEI, KS=KSOL2LEI
  SOL3LEI : SOLE, TYPE="APEX", L=LSOL3LEI/2, APER=RSOL3LEI, KS=KSOL3LEI

! ==============================================================================
! DRIF
! ------------------------------------------------------------------------------

! gun to L0LEI

  DGLEI1  : DRIF, L=0.191-LSOL1LEI/2
  DGLEI2  : DRIF, L=(0.91-0.191)-LSOL1LEI/2-LBUN1LEI/2
  DGLEI3  : DRIF, L=(1.88-0.91)-LBUN1LEI/2-LSOL2LEI/2
  DGLEI4  : DRIF, L=(3.40-1.88)-LSOL2LEI/2-LBUN2LEI/2
  DGLEI5  : DRIF, L=(4.80-3.40)-LBUN2LEI/2-LSOL3LEI/2
  DGLEI6  : DRIF, L=0.34225 !cathode to center of CM001 = 6.5 m

  DGLEI2a : DRIF, L=(DGLEI2[L]-0.4)/2
  DGLEI2b : DRIF, L=0.1
  DGLEI2c : DRIF, L=0.1
  DGLEI2d : DRIF, L=0.1
  DGLEI2e : DRIF, L=0.1
  DGLEI2f : DRIF, L=(DGLEI2[L]-0.4)/2
  DGLEI3a : DRIF, L=(DGLEI3[L]-0.3)/2
  DGLEI3b : DRIF, L=0.1
  DGLEI3c : DRIF, L=0.1
  DGLEI3d : DRIF, L=0.1
  DGLEI3e : DRIF, L=(DGLEI3[L]-0.3)/2
  DGLEI4a : DRIF, L=(DGLEI4[L]-0.2)/2
  DGLEI4b : DRIF, L=0.1
  DGLEI4c : DRIF, L=0.1
  DGLEI4d : DRIF, L=(DGLEI4[L]-0.2)/2
  DGLEI5a : DRIF, L=(DGLEI5[L]-0.2)/2
  DGLEI5b : DRIF, L=0.1
  DGLEI5c : DRIF, L=0.1
  DGLEI5d : DRIF, L=(DGLEI5[L]-0.2)/2
  DGLEI6a : DRIF, L=(DGLEI6[L]-0.1)/2
  DGLEI6b : DRIF, L=0.1
  DGLEI6c : DRIF, L=(DGLEI6[L]-0.1)/2

! CM00 to dogleg

  LD0D14 := 3.827898 !sum of drifts D0D01-04

  D0D00  : DRIF, L=0.407975
  D0D01  : DRIF, L=0.427898
  D0D02  : DRIF, L=1.3
  D0D04  : DRIF, L=0.8
  D0D03  : DRIF, L=LD0D14-(D0D01[L]+D0D02[L]+D0D04[L])

  D0D00b : DRIF, L=0.291975
  D0D00a : DRIF, L=D0H00[L]-Ljaw-D0H00b[L]
  D0D01b : DRIF, L=0.205
  D0D01a : DRIF, L=D0D01[L]-D0D01b[L]
  D0D02b : DRIF, L=0.205
  D0D02a : DRIF, L=D0D02[L]-D0D02b[L]
  D0D03c : DRIF, L=0.205
  D0D03a : DRIF, L=(D0D03[L]-D0D03c[L])/2-TCXDGI[L]
  D0D03b : DRIF, L=D0D03a[L]
  D0D04b : DRIF, L=0.5
  D0D04a : DRIF, L=D0D04[L]-D0D04b[L]

! dogleg

  XDLI     := -6.0            !total X-displacement
  LDLIB2B3 :=  8.257018443718 !distance between BDLI2 and BDLI3

  DDLI01 : DRIF, L=0.85-LQx/2
  DDLI02 : DRIF, L=DDLI01[L]
  DDLI04 : DRIF, L=0.5
  DDLI05 : DRIF, L=DDLI04[L]
  DDLI06 : DRIF, L=4.6
  DDLI03 : DRIF, L=LDLIB2B3/2-3*LQx-DDLI04[L]-DDLI05[L]-DDLI06[L]/2
  DDLI07 : DRIF, L=DDLI05[L]
  DDLI08 : DRIF, L=DDLI04[L]
  DDLI09 : DRIF, L=DDLI03[L]
  DDLI10 : DRIF, L=DDLI02[L]
  DDLI11 : DRIF, L=DDLI01[L]

  DDLI02a  : DRIF, L=0.25-Ljaw/2
  DDLI02b  : DRIF, L=0.25-Ljaw/2
  DDLI02c  : DRIF, L=DDLI02[L]-DDLI02a[L]-DDLI02b[L]-Ljaw
  DDLI03b  : DRIF, L=0.1594
  DDLI03a  : DRIF, L=DDLI03[L]-DDLI03b[L]
  DDLI04b  : DRIF, L=0.1594
  DDLI04a  : DRIF, L=DDLI04[L]-DDLI04b[L]
  DDLI05b  : DRIF, L=0.1594
  DDLI05a  : DRIF, L=DDLI05[L]-DDLI05b[L]
  DDLI06h  : DRIF, L=DDLI06[L]/2
  DDLI06a  : DRIF, L=1.0239-LQx/2
  DDLI06b  : DRIF, L=0.450
  DDLI06c  : DRIF, L=1.8781-1.0239-0.450
  DLIWALL  : DRIF, L=1.5 !concrete & iron shield wall
  DLIWALLa : DRIF, L=0.4759 !to center of DLI dogleg
  DLIWALLb : DRIF, L=DLIWALL[L]-DLIWALLa[L]
  DDLI06d  : DRIF, L=2.450-DDLI06c[L]-DLIWALL[L]
  DDLI06e  : DRIF, L=DDLI06[L]-DDLI06a[L]-DDLI06b[L]-DDLI06c[L] &
                    -DLIWALL[L]-DDLI06d[L]
  DDLI07a : DRIF, L=0.1886
  DDLI07b : DRIF, L=DDLI07[L]-DDLI07a[L]
  DDLI08a : DRIF, L=0.1886
  DDLI08b : DRIF, L=DDLI08[L]-DDLI08a[L]
  DDLI09a : DRIF, L=0.1886
  DDLI09b : DRIF, L=DDLI09[L]-DDLI09a[L]
  DDLI10b : DRIF, L=0.1594
  DDLI10a : DRIF, L=DDLI10[L]-DDLI10b[L]

! ==============================================================================
! BPMs
! ------------------------------------------------------------------------------

  BPM1LEI : MONI, TYPE="Stripline-4"
  BPM2LEI : MONI, TYPE="Stripline-4"
  BPM3LEI : MONI, TYPE="Stripline-4"
  BPM4LEI : MONI, TYPE="Stripline-4"

  BPM0D01 : MONI, TYPE="Stripline-12"
  BPM0D02 : MONI, TYPE="Stripline-12"
  BPM0D03 : MONI, TYPE="Stripline-12"
  BPM0D04 : MONI, TYPE="Stripline-12"

  BPMDLI01 : MONI, TYPE="Stripline-1"
  BPMDLI02 : MONI, TYPE="Stripline-1"
  BPMDLI03 : MONI, TYPE="Stripline-1"
  BPMDLI04 : MONI, TYPE="Stripline-1"
  BPMDLI05 : MONI, TYPE="Stripline-1"
  BPMDLI06 : MONI, TYPE="Stripline-1"
  BPMDLI07 : MONI, TYPE="Stripline-1"
  BPMDLI08 : MONI, TYPE="Stripline-1"

  RFB0D00 : MONI, TYPE="@2,CavityS-1"

! ==============================================================================
! XCORs
! ------------------------------------------------------------------------------

  XC01LEI : HKIC, TYPE="LBNL-xy"
  XC02LEI : HKIC, TYPE="LBNL-xy"
  XC03LEI : HKIC, TYPE="LBNL-xy"
  XC04LEI : HKIC, TYPE="LBNL-xy"
  XC05LEI : HKIC, TYPE="LBNL-xy"
  XC06LEI : HKIC, TYPE="LBNL-xy"
  XC07LEI : HKIC, TYPE="LBNL-xy"
  XC08LEI : HKIC, TYPE="LBNL-xy"

  XC0D02 : HKIC, TYPE="class-1a"
  XC0D03 : HKIC, TYPE="class-1a"
  XC0D04 : HKIC, TYPE="class-1a"
  XC0D05 : HKIC, TYPE="class-1a"

  XCDLI01 : HKIC, TYPE="class-6"
  XCDLI03 : HKIC, TYPE="class-6"
  XCDLI06 : HKIC, TYPE="class-6"
  XCDLI08 : HKIC, TYPE="class-6"

! ==============================================================================
! YCORs
! ------------------------------------------------------------------------------

  YC01LEI : HKIC, TYPE="LBNL-xy"
  YC02LEI : HKIC, TYPE="LBNL-xy"
  YC03LEI : HKIC, TYPE="LBNL-xy"
  YC04LEI : HKIC, TYPE="LBNL-xy"
  YC05LEI : HKIC, TYPE="LBNL-xy"
  YC06LEI : HKIC, TYPE="LBNL-xy"
  YC07LEI : HKIC, TYPE="LBNL-xy"
  YC08LEI : HKIC, TYPE="LBNL-xy"

  YC0D02 : HKIC, TYPE="class-1a"
  YC0D03 : HKIC, TYPE="class-1a"
  YC0D04 : HKIC, TYPE="class-1a"
  YC0D05 : HKIC, TYPE="class-1a"

  YCDLI02 : VKIC, TYPE="class-6"
  YCDLI04 : VKIC, TYPE="class-6"
  YCDLI05 : VKIC, TYPE="class-6"
  YCDLI07 : VKIC, TYPE="class-6"

! ==============================================================================
! collimators and stoppers
! ------------------------------------------------------------------------------

! instruments

  CATHODELEI : INST
  VV01LEI    : INST
  IM01LEI    : IMON, TYPE="ICT"
  AM00LEI    : INST !gun laser injection mirror
  YAG01LEI   : PROF, TYPE="YAG INJ"
  VV02LEI    : INST

! halo/dark current collimator

  PC0D00 : ECOL, L=Ljaw, XSIZE=6.0e-3, YSIZE=6.0e-3, TYPE="tungsten"

! energy collimator (horizontal half-aperture for 3% energy spread;
! default out-of-plane half-aperture is 20 mm)

  CEDLI : RCOL, L=Ljaw, XSIZE=6.25E-3, YSIZE=20.E-3, TYPE="HCOLL"

! dogleg stoppers (required by RP)

  STDLI1 : INST
  STDLI2 : INST
  STDLI3 : INST

! ==============================================================================
! markers
! ------------------------------------------------------------------------------

  MTCXDGI : MARK !center of TCAV
  CNTDLI  : MARK !center of DLI dogleg

! ==============================================================================
! BEAMLINE
! ------------------------------------------------------------------------------

  SOL1LEI_full : LINE=(SOL1LEI,CQ01LEI,SQ01LEI,SOL1LEI)
  BUN1LEI_full : LINE=(BUN1LEI,BUN1LEI)
  SOL2LEI_full : LINE=(SOL2LEI,CQ02LEI,SQ02LEI,SOL2LEI)
  BUN2LEI_full : LINE=(BUN2LEI,BUN2LEI)
  SOL3LEI_full : LINE=(SOL3LEI,CQ03LEI,SQ03LEI,SOL3LEI)

  SC1LEI : LINE=(XC01LEI,YC01LEI)
  SC2LEI : LINE=(XC02LEI,YC02LEI)
  SC3LEI : LINE=(XC03LEI,YC03LEI)
  SC4LEI : LINE=(XC04LEI,YC04LEI)
  SC5LEI : LINE=(XC05LEI,YC05LEI)
  SC6LEI : LINE=(XC06LEI,YC06LEI)
  SC7LEI : LINE=(XC07LEI,YC07LEI)
  SC8LEI : LINE=(XC08LEI,YC08LEI)

  Q0D01_full  : LINE=(Q0D01,BPM0D01,Q0D01)
  Q0D02_full  : LINE=(Q0D02,BPM0D02,Q0D02)
  Q0D03_full  : LINE=(Q0D03,BPM0D03,Q0D03)
  TCXDGI_full : LINE=(TCXDGI,MTCXDGI,TCXDGI)
  Q0D04_full  : LINE=(Q0D04,BPM0D04,Q0D04)

  BXDLI1_full  : LINE=(BXDLI1a,BXDLI1b)
  QDLI1_full   : LINE=(QDLI1,BPMDLI01,QDLI1)
  BXDLI2_full  : LINE=(BXDLI2a,BXDLI2b)
  QDLI2_full   : LINE=(QDLI2,BPMDLI02,QDLI2)
  QDLI3_full   : LINE=(QDLI3,BPMDLI03,QDLI3)
  QDLI4_full   : LINE=(QDLI4,BPMDLI04,QDLI4)
  DLIWALL_full : LINE=(DLIWALLa,CNTDLI,DLIWALLb)
  QDLI5_full   : LINE=(QDLI5,BPMDLI05,QDLI5)
  QDLI6_full   : LINE=(QDLI6,BPMDLI06,QDLI6)
  QDLI7_full   : LINE=(QDLI7,BPMDLI07,QDLI7)
  BXDLI3_full  : LINE=(BXDLI3a,BXDLI3b)
  QDLI8_full   : LINE=(QDLI8,BPMDLI08,QDLI8)
  BXDLI4_full  : LINE=(BXDLI4a,BXDLI4b)

  SC0D02 : LINe=(XC0D02,YC0D02)
  SC0D03 : LINe=(XC0D03,YC0D03)
  SC0D04 : LINe=(XC0D04,YC0D04)
  SC0D05 : LINe=(XC0D05,YC0D05)

  COMMENT !simplified
    GUNLEI : LINE=(BEGGUNLEI,&
      CATHODELEI,DGLEI1,&
      SOL1LEI_full,DGLEI2,&
      BUN1LEI_full,DGLEI3,&
      SOL2LEI_full,DGLEI4,&
      BUN2LEI_full,DGLEI5,&
      SOL3LEI_full,DGLEI6,&
      ENDGUNLEI)
  ENDCOMMENT

 !COMMENT !complete
    GUNLEI : LINE=(BEGGUNLEI,&
      CATHODELEI,DGLEI1,&
      SOL1LEI_full,DGLEI2a,VV01LEI,DGLEI2b,SC1LEI,DGLEI2c,BPM1LEI,DGLEI2d,&
        IM01LEI,DGLEI2e,SC2LEI,DGLEI2f,&
      BUN1LEI_full,DGLEI3a,SC3LEI,DGLEI3b,AM00LEI,DGLEI3c,SC4LEI,DGLEI3d,&
        YAG01LEI,DGLEI3e,&
      SOL2LEI_full,DGLEI4a,VV02LEI,DGLEI4b,BPM2LEI,DGLEI4c,SC5LEI,DGLEI4d,&
      BUN2LEI_full,DGLEI5a,SC6LEI,DGLEI5b,BPM3LEI,DGLEI5c,SC7LEI,DGLEI5d,&
      SOL3LEI_full,DGLEI6a,BPM4LEI,DGLEI6b,SC8LEI,DGLEI6c,&
      ENDGUNLEI)
 !ENDCOMMENT

  COMMENT !simplified
    LEI_1 : LINE=(BEGLEI_1,&
      D0D00,&
      Q0D01,Q0D01,D0D01,&
      Q0D02,Q0D02,D0D02,&
      Q0D03,Q0D03,D0D03,&
      Q0D04,Q0D04,D0D04,&
      ENDLEI_1)
    LEI_2 : LINE=(BEGLEI_2,&
      BXDLI1a,BXDLI1b,DDLI01,&
      QDLI1,QDLI1,DDLI02,&
      BXDLI2a,BXDLI2b,DDLI03,&
      QDLI2,QDLI2,DDLI04,&
      QDLI3,QDLI3,DDLI05,&
      QDLI4,QDLI4,DDLI06h,CNTDLI,DDLI06h,&
      QDLI5,QDLI5,DDLI07,&
      QDLI6,QDLI6,DDLI08,&
      QDLI7,QDLI7,DDLI09,&
      BXDLI3a,BXDLI3b,DDLI10,&
      QDLI8,QDLI8,DDLI11,&
      BXDLI4a,BXDLI4b,&
      ENDLEI_2)
  ENDCOMMENT

 !COMMENT !complete
    LEI_1 : LINE=(BEGLEI_1,&
      RFB0D00,D0D00a,PC0D00,D0D00b,&
      Q0D01_full,D0D01a,SC0D02,D0D01b,&
      Q0D02_full,D0D02a,SC0D03,D0D02b,&
      Q0D03_full,D0D03a,TCXDGI_full,D0D03b,SC0D04,D0D03c,&
      Q0D04_full,D0D04a,SC0D05,D0D04b,&
      ENDLEI_1)
    LEI_2 : LINE=(BEGLEI_2,&
      BXDLI1_full,DDLI01,&
      QDLI1_full,DDLI02a,CEDLI,DDLI02b,XCDLI01,DDLI02c,&
      BXDLI2_full,DDLI03a,YCDLI02,DDLI03b,&
      QDLI2_full,DDLI04a,XCDLI03,DDLI04b,&
      QDLI3_full,DDLI05a,YCDLI04,DDLI05b,&
      QDLI4_full,DDLI06a,STDLI1,DDLI06b,STDLI2,DDLI06c,&
        DLIWALL_full,DDLI06d,STDLI3,DDLI06e,&
      QDLI5_full,DDLI07a,YCDLI05,DDLI07b,&
      QDLI6_full,DDLI08a,XCDLI06,DDLI08b,&
      QDLI7_full,DDLI09a,YCDLI07,DDLI09b,&
      BXDLI3_full,DDLI10a,XCDLI08,DDLI10b,&
      QDLI8_full,DDLI11,&
      BXDLI4_full,&
      ENDLEI_2)
 !ENDCOMMENT

  LEI : LINE=(LEI_1,LEI_2)

! ------------------------------------------------------------------------------

  RETURN