! *** OPTICS=LCLS2sc28NOV16 ***

! LCLS2sc A-line

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 02-NOV-2016, Y. Nosochkov
!  * replace fast kicker/septum magnets with 120 Hz pulsed magnets (deferred)
!    for ESTB (D. McCormick, J. Amann)
!  * the pulsed magnets and other ESTB devices are not funded by LCLS-II (Paul)
!  * update eng. type of BXAM1 from 1.0D38.37 to 2.0D38.37 (J. Amann)
!  * move to baseline: PCBSY2, BTMBSY2
! ------------------------------------------------------------------------------
! 24-JUN-2016, Y. Nosochkov
!  * add deferred BPMCUA between A-line kicker and septum
!  * update the engineering type of BKYAL1,...,BKYAL5 kickers to
!    "0.787K35.4" (J. Amann)
! ------------------------------------------------------------------------------
! 26-FEB-2016, M. Woodley
!  * remove SEQnn MARKers
! 26-FEB-2016, Y. Nosochkov
!  * add BCS PCBSY2/BTMBSY2 at Z=3124 m (deferred @0) (S. Mao)
!  * increase distance between kickers from 15 cm to 30 cm
! ------------------------------------------------------------------------------
! 25-SEP-2015, Y. Nosochkov
!  * update definitions of kickers and septum to allow zero angle
! 24-AUG-2015, Y. Nosochkov
!  * update the TYPE of septum from 0.39SD38.98 to 0.625SD38.98 (J. Amann)
!  * adjust quad strengths for match to the updated BSY optics
!  * match geometry to the updated positions of A-line kicker & septum
! ------------------------------------------------------------------------------
! 20-MAR-2015, M. Woodley
!  * add SEQ21BEG, SEQ21END, BEGBSYA, ENDBSYA MARKERs
! 12-MAR-2015, Y. Nosochkov
!  * add fast kickers and septum (as in spreader) to deflect beam into A-line
!  * A-line optics based on original design per M. Woodley's deck
! ------------------------------------------------------------------------------

! ==============================================================================
! dipoles
! ------------------------------------------------------------------------------

! yawed pulsed magnets

  GBXAPM := 35.687E-3      !1.405K40.83 pulsed magnet gap (m)
  SBXAPM := 1.055          !PM eff. straight length (m)
  TBXAPM := 0.014303833885 !PM tilt angle (rad)

  ABXAPM0  := -0.276615051231E-2
  ABXAPM   := ABXAPM0 *SETAL !angle per one PM (rad)
  ABXAPMh  := ABXAPM/2       !PM half-angle
  ABXAPMh2 := ABXAPMh *ABXAPMh
  ABXAPMh4 := ABXAPMh2*ABXAPMh2

  LBXAPM := SBXAPM/(1 -ABXAPMh2/6 +ABXAPMh4/120) !PM path length

  BKXAPM1a : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E1=ABXAPM/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBXAPM/2, TILT=TBXAPM
  BKXAPM1b : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E2=ABXAPM/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBXAPM/2, TILT=TBXAPM

  BKXAPM2a : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E1=ABXAPM/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBXAPM/2, TILT=TBXAPM
  BKXAPM2b : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E2=ABXAPM/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBXAPM/2, TILT=TBXAPM

  BKXAPM3a : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E1=ABXAPM/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBXAPM/2, TILT=TBXAPM
  BKXAPM3b : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E2=ABXAPM/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBXAPM/2, TILT=TBXAPM

  BKXAPM4a : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E1=ABXAPM/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBXAPM/2, TILT=TBXAPM
  BKXAPM4b : SBEN, TYPE="@3,1.405K40.83", L=LBXAPM/2, ANGLE=ABXAPM/2, &
    E2=ABXAPM/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBXAPM/2, TILT=TBXAPM

! PM projections onto BSY HXR beam

  ZBXAPM1 := SBXAPM*COS(ABXAPM0*1/2)
  ZBXAPM2 := SBXAPM*COS(ABXAPM0*3/2)
  ZBXAPM3 := SBXAPM*COS(ABXAPM0*5/2)
  ZBXAPM4 := SBXAPM*COS(ABXAPM0*7/2)

  DBKXAPM1a : DRIF, L=ZBXAPM1/2 ; DBKXAPM1b : DRIF, L=ZBXAPM1/2
  DBKXAPM2a : DRIF, L=ZBXAPM2/2 ; DBKXAPM2b : DRIF, L=ZBXAPM2/2
  DBKXAPM3a : DRIF, L=ZBXAPM3/2 ; DBKXAPM3b : DRIF, L=ZBXAPM3/2
  DBKXAPM4a : DRIF, L=ZBXAPM4/2 ; DBKXAPM4b : DRIF, L=ZBXAPM4/2

! A-line merge bend 

  GBXAM := 50.8E-3                      !2.0D38.37 gap height (m)
  SBXAM := 1.025                        !2.0D38.37 straight length (m)
  ABXAM := 0.232611190004E-2            !bend angle (rad)
  LBXAM := SBXAM*ABXAM/(2*SIN(ABXAM/2)) !path length (m)

  BXAM1A : SBEN, TYPE="@3,2.0D38.37", L=LBXAM/2, ANGLE=ABXAM/2, &
                 E1=ABXAM/2, E2=0, HGAP=GBXAM/2, FINT=0.5, FINTX=0
  BXAM1B : SBEN, TYPE="@3,2.0D38.37", L=LBXAM/2, ANGLE=ABXAM/2, &
                 E2=ABXAM/2, E1=0, HGAP=GBXAM/2, FINT=0,   FINTX=0.5

! A-bends

  !AARC  := -24*RADDEG !total arc bend angle (24 degrees)
  !Nbend := 12         !number of arc bends
  !ABA   := AARC/Nbend !arc bend angle
  ABA   := -1.999526617334*RADDEG !arc bend angle per Transport deck

  LBA := 3.024 !present A-line bends
  GBA := 0.06  !Blue Book value

  BA1 : SBEN, L=LBA/2, HGAP=GBA/2, ANGLE=ABA/2, E1=ABA/2, FINT=0.5, FINTX=0
  BA2 : SBEN, L=LBA/2, HGAP=GBA/2, ANGLE=ABA/2, E2=ABA/2, FINT=0, FINTX=0.5

  BA  : LINE=(BA1,BA2)

! ==============================================================================
! quadrupoles
! ------------------------------------------------------------------------------

  LQ8cm := 2.0
  rQ8cm := 0.08/2
  LQ19  := 2.0
  rQ19  := 0.186/2
  LQ20  := 1.31318
  rQ20  := 8.25*0.0254/2
  LSQ   := 0.55
  rSQ   := 0.08/2

  !KQ10 :=  0.040190926401
  !KQ11 := -0.037926743862
  !KQ19 :=  0.029507959162    !0.032191661707
  !KQ20 :=  0.961853807504E-2 !0.20869827928E-2
  !KQ27 := -0.06339026
  !KQ28 :=  0.03715726
  !KQ30 := -0.03054855
  !KQ38 :=  0.03460619

! note-1: the K-values below are for SC beam; the settings for Cu beam are
! in the "LCLS2cu_main.mad8" file
! note-2: duplicate these settings in SETK2scA in "LCLS2sc_main.mad8"

  KQ10 :=  0.040562593923
  KQ11 := -0.033577157433
  KQ19 :=  0.028596205953
  KQ20 :=  0.012609992225
  KQ27 := -0.061763391269
  KQ28 :=  0.03154138433
  KQ30 := -0.030289938043
  KQ38 :=  0.034801871726

  Q10 : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ10
  Q11 : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ11
  Q19 : QUAD, L=LQ19/2,  APER=rQ19,  K1=KQ19
  Q20 : QUAD, L=LQ20/2,  APER=rQ20,  K1=KQ20
  Q27 : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ27
  Q28 : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ28
  Q30 : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ30
  Q38 : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ38

  KSQ := 0.0

  "SQ27.5" : QUAD, L=LSQ/2,   APER=rSQ,   K1=KSQ, TILT

! ==============================================================================
! drifts
! ------------------------------------------------------------------------------

 !D105  : DRIF, L=5.5372
  D105a : DRIF, L=3.598
  D105b : DRIF, L=5.5372-D105a[L]
  D106  : DRIF, L=0.727
  D107  : DRIF, L=0.7755
  D108  : DRIF, L=3.84839
  D109  : DRIF, L=0.7755
  D110  : DRIF, L=3.84839
  D111  : DRIF, L=0.7755
 !D112  : DRIF, L=15.74899
  D112b : DRIF, L=1.396
  D112a : DRIF, L=15.74899-D112b[L]
  D113  : DRIF, L=9.0997
  D114  : DRIF, L=5.94572
  D115  : DRIF, L=0.7755
  D116  : DRIF, L=3.84839
  D117  : DRIF, L=0.7755
  D118  : DRIF, L=3.84839
  D119  : DRIF, L=0.7755
  D120  : DRIF, L=1.744768 !1.74477
  D121  : DRIF, L=1.525
  D122  : DRIF, L=1.925
  D123  : DRIF, L=38.1116
  D124  : DRIF, L=21.4778
  D125  : DRIF, L=5.04065
  D126  : DRIF, L=76.23456
  D127  : DRIF, L=92.118

  D126a : DRIF, L=15.322492
  D126b : DRIF, L=9.72325
  D126c : DRIF, L=D126[L]-(D126a[L]+D126b[L])

  ZPCAPM  := 0.1824 !length of PM collimator aligned along BSY HXR beam
  LPCAPM1 := ZPCAPM/COS(1*ABXAPM)
  LPCAPM2 := ZPCAPM/COS(2*ABXAPM)
  LPCAPM3 := ZPCAPM/COS(3*ABXAPM)
  LPCAPM4 := ZPCAPM/COS(4*ABXAPM)

  LDAPM  := 0.5951 !space between two PMs along A-line trajectory
  LDAPM1 := (LDAPM-LPCAPM1)/2
  LDAPM2 := (LDAPM-LPCAPM2)/2
  LDAPM3 := (LDAPM-LPCAPM3)/2
  LDAPM4 := (LDAPM-LPCAPM4)/2

  DAPM1 : DRIF, L=LDAPM1
  DAPM2 : DRIF, L=LDAPM2
  DAPM3 : DRIF, L=LDAPM3
  DAPM4 : DRIF, L=LDAPM4

  LPCBSY2 := LPCSP/COS(4*ABXAPM) !length of PCBSY2 aligned along BSY HXR beam

  LDA01 := 0.0471765+0.15 !check with Stan position of PCBSY2
  LDA02 := 4.371494-LDA01-LPCSP/COS(4*ABXAPM0)
  LDA03 := 1.3206
  LDA04 := 48.451380526704

  DA01   : DRIF, L=LDA01
  DA02   : DRIF, L=LDA02
  DA03   : DRIF, L=LDA03
  DA04   : DRIF, L=LDA04
  DAMQ10 : DRIF, L=0.9875

! A-line drifts projected onto BSY HXR beamline

  LDZAPM1 := (LDAPM*COS(1*ABXAPM0)-ZPCAPM)/2
  LDZAPM2 := (LDAPM*COS(2*ABXAPM0)-ZPCAPM)/2
  LDZAPM3 := (LDAPM*COS(3*ABXAPM0)-ZPCAPM)/2
  LDZAPM4 := (LDAPM*COS(4*ABXAPM0)-ZPCAPM)/2
  LDZA01  :=  LDA01*COS(4*ABXAPM0)
  LDZA02  :=  LDA02*COS(4*ABXAPM0)

  DZAPM1 : DRIF, L=LDZAPM1
  DZAPM2 : DRIF, L=LDZAPM2
  DZAPM3 : DRIF, L=LDZAPM3
  DZAPM4 : DRIF, L=LDZAPM4
  DZA01  : DRIF, L=LDZA01
  DZA02  : DRIF, L=LDZA02

! ==============================================================================
! diagnostic, collimation
! ------------------------------------------------------------------------------

  PR10  : PROF
  PR18  : PROF
  PRAPM : PROF, TYPE="@3,PHOSPHOR"

  D105 : LINE=(D105a,PR10,D105b)
  D112 : LINE=(D112a,PR18,D112b)

  PCAPM1 : ECOL, TYPE="@3,MPS PC", L=LPCAPM1, XSIZE=44.45E-3, YSIZE=6.35E-3
  PCAPM2 : ECOL, TYPE="@3,MPS PC", L=LPCAPM2, XSIZE=44.45E-3, YSIZE=6.35E-3
  PCAPM3 : ECOL, TYPE="@3,MPS PC", L=LPCAPM3, XSIZE=44.45E-3, YSIZE=6.35E-3
  PCAPM4 : ECOL, TYPE="@3,MPS PC", L=LPCAPM4, XSIZE=44.45E-3, YSIZE=6.35E-3

! dump with 2 holes for A-line and LCLS2 -- aligned on BSY HXR line

  DUMPBSYA : INST, TYPE="@3", L=0.45/COS(4*ABXAPM)

! ==============================================================================
! BCS devices
! ------------------------------------------------------------------------------

  PCBSY2 : ECOL, TYPE="BCS PC", L=LPCBSY2, &
                 XSIZE=27.94E-3, YSIZE=27.94E-3 !BCS PC in BSY (2.2" diameter)

  BTMBSY2 : INST, TYPE="BCS BTM" !Burn-Through-Monitor behind PCBSY2

! ==============================================================================
! coordinate rolls ... bend plane rotated to remove linac slope
! ------------------------------------------------------------------------------

  ROLLON := 1.0

  !ROLL1 : SROT, ANGLE= 0.014303845885    * ROLLON
  !ROLL2 : SROT, ANGLE=-0.393462907527E-2 * ROLLON
  !ROLL3 : SROT, ANGLE=-0.011395368282    * ROLLON

  !ROLL1 : SROT, ANGLE= -0.081073470970    * ROLLON
  ROLL4 : SROT, ANGLE=  0.014303788803    * ROLLON
  ROLL2 : SROT, ANGLE= -0.399639784046E-2 * ROLLON
  ROLL3 : SROT, ANGLE=  0.0               * ROLLON !no ROLL3 per alignment group

! ==============================================================================
! markers
! ------------------------------------------------------------------------------

  BEGB     : MARK
  ENDB     : MARK
  ALWALL   : MARK
  ESAW     : MARK
  PVOT     : MARK
  ESAE     : MARK
  BMDE     : MARK
  MARC     : MARK !match point
  BEGALINE : MARK

! ==============================================================================
! beamlines
! ------------------------------------------------------------------------------

  LD126 : LINE=(D126a,ESAW,D126b,PVOT,D126c)

  ALINEa : LINE=(&
    BKXAPM1a,BKXAPM1b,DAPM1,PCAPM1,DAPM1,&
    BKXAPM2a,BKXAPM2b,DAPM2,PCAPM2,DAPM2,&
    BKXAPM3a,BKXAPM3b,DAPM3,PCAPM3,DAPM3,&
    BKXAPM4a,BKXAPM4b,DAPM4,PCAPM4,DA01,PCBSY2,BTMBSY2,DA02,DUMPBSYA)

  ALINEb : LINE=(DA03,PRAPM,DA04)

  ALINEc : LINE=(&
    ROLL4,&
    BXAM1A,BXAM1B,ROLL2,&
    ENDBSYA,DAMQ10,&
    Q10,Q10,D105,&
    Q11,Q11,D106,&
    BEGB,&
    BA,D107,&
    BA,D108,&
    BA,D109,&
    BA,D110,&
    BA,D111,&
    BA,D112,&
    Q19,Q19,D113,&
    Q20,Q20,D114,&
    BA,D115,&
    BA,D116,&
    BA,D117,&
    BA,D118,&
    BA,D119,&
    BA,MARC,ROLL3,&
    ENDB,D120,&
    Q27,Q27,D121,&
    "SQ27.5","SQ27.5",D122,&
    Q28,Q28,D123,&
    Q30,Q30,D124,&
    Q38,Q38,D125,ALWALL,LD126,ESAE,D127,BMDE)

  ALINE : LINE=(BEGBSYA,ALINEa,ALINEb,ALINEc)

! ------------------------------------------------------------------------------

  RETURN