! *** OPTICS=LCLS2sc19JUN15 ***

! LCLS2sc transport from Cu-linac to SXR

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 19-JUN-2015, Y. Nosochkov
!  * add additional deferred quadrupole at center of CUSXR
!  * rename some magnets/devices to put the names in order
!  * change magnet type of QCuS4, QCuS5, QCuS6, QCuS7 from 2Q10 to 1.085Q4.31
!  * change BPM type at 2Q10 to Stripline-5, and at 1.085Q4.31 to Stripline-2
!  * move BPMs outside of the quads
!  * adjust distance from BPM/corr to the quad
! 20-MAR-2015, M. Woodley
!  * move definitions of BEGCuSXR and ENDCuSXR MARKERs to common.xsif
!  * add SEQ20BEG and SEQ20END MARKERs
! 12-MAR-2015, Y. Nosochkov
!  * add a dogleg transport line from Cu-linac to SXR (deferred to level 3)
! ------------------------------------------------------------------------------

! XYZ (linac system) and Twiss at entrance of the first bend (BEGCUSXR)

  XCuS1  := -3.310074536E-07 !per existing LCLS-1 coordinates
  YCuS1  :=  0.0
  ZCuS1  :=  3064.696790
  THCuS1 :=  0.0
  PHCuS1 :=  0.0
  PSCuS1 :=  0.0

  TBXCuS1 :=  5.138874742E+01
  TBYCuS1 :=  5.132779090E+01
  TAXCuS1 := -1.303698686
  TAYCuS1 :=  1.135912384
  TWSCuS1 : BETA0, BETX=TBXCuS1, BETY=TBYCuS1, ALFX=TAXCuS1, ALFY=TAYCuS1

! XYZ (linac system) and Twiss at exit of the last bend

  XCuS2  := -25.610*IN2M
  YCuS2  :=  25.570*IN2M
  ZCuS2  :=  3139.196790
  THCuS2 :=  0.0
  PHCuS2 :=  0.0
  PSCuS2 :=  0.0

  TBXCuS2 :=  5.138874676E+01
  TBYCuS2 :=  5.132779082E+01
  TAXCuS2 :=  1.303699220
  TAYCuS2 := -1.135912461
  TWSCuS2 : BETA0, BETX=TBXCuS2, BETY=TBYCuS2, ALFX=TAXCuS2, ALFY=TAYCuS2

! quads (stronger quads are needed for 15 GeV)

  KQCUS1  :=  0.536404175186
  KQCUS2  := -0.537076666724
  KQCUS3  := -0.373586600631
  KQCUS4  :=  3.396251116325
  KQCUS5  := -2.7
  KQCUS6  :=  KQCUS5
  KQCuS7  :=  KQCuS4
  KQCuS8  :=  KQCuS3
  KQCuS9  :=  KQCuS2
  KQCuS10 :=  KQCUS1

  QCuS1  : QUAD, TYPE="@3,2Q10"      , L=LQR/2, K1=KQCuS1 , APER=rQR
  QCuS2  : QUAD, TYPE="@3,2Q10"      , L=LQR/2, K1=KQCuS2 , APER=rQR
  QCuS3  : QUAD, TYPE="@3,2Q10"      , L=LQR/2, K1=KQCuS3 , APER=rQR
  QCuS4  : QUAD, TYPE="@3,1.085Q4.31", L=LQE/2, K1=KQCuS4 , APER=rQE
  QCuS5  : QUAD, TYPE="@3,1.085Q4.31", L=LQE/2, K1=KQCuS5 , APER=rQE
  QCuS6  : QUAD, TYPE="@3,1.085Q4.31", L=LQE/2, K1=KQCuS6 , APER=rQE
  QCuS7  : QUAD, TYPE="@3,1.085Q4.31", L=LQE/2, K1=KQCuS7 , APER=rQE
  QCuS8  : QUAD, TYPE="@3,2Q10"      , L=LQR/2, K1=KQCuS8 , APER=rQR
  QCuS9  : QUAD, TYPE="@3,2Q10"      , L=LQR/2, K1=KQCuS9 , APER=rQR
  QCuS10 : QUAD, TYPE="@3,2Q10"      , L=LQR/2, K1=KQCuS10, APER=rQR

! outer rolled bends

  ZBRCuS  := 1.0    !bend straight length (1.0D38.37) (m)
  GBRCuS  := 0.0254 !bend gap height (m)

  ABRCuS :=  0.012533627559
  LBRCuS :=  ZBRCuS*ABRCuS/(2*SIN(ABRCuS/2)) !bend path length (m)
  TBRCuS := -0.786843658049                  !bend roll angle (rad)

  BRCuS1a : SBEN, TYPE="@3,1.0D38.37", L=LBRCuS/2, ANGLE= ABRCuS/2, &
            E1= ABRCuS/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBRCuS/2, TILT=TBRCuS
  BRCuS1b : SBEN, TYPE="@3,1.0D38.37", L=LBRCuS/2, ANGLE= ABRCuS/2, &
            E2= ABRCuS/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBRCuS/2, TILT=TBRCuS

  BRCuS2a : SBEN, TYPE="@3,1.0D38.37", L=LBRCuS/2, ANGLE=-ABRCuS/2, &
            E1=-ABRCuS/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBRCuS/2, TILT=TBRCuS
  BRCuS2b : SBEN, TYPE="@3,1.0D38.37", L=LBRCuS/2, ANGLE=-ABRCuS/2, &
            E2=-ABRCuS/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBRCuS/2, TILT=TBRCuS

! inner vertical bends

  ZBYCuS  := 0.6    !bend straight length (m)
  GBYCuS  := 0.0254 !bend full gap (m)

  ABYCuS  := 0.101252150875E-2
  LBYCuS  := ZBYCuS*ABYCuS/(2*SIN(ABYCuS/2)) !bend path length (m)

  BYCuS1a : SBEN, TYPE="@3,1.0D22.625", L=LBYCuS/2, ANGLE= ABYCuS/2, &
            E1= ABYCuS/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBYCuS/2, TILT=PI/2
  BYCuS1b : SBEN, TYPE="@3,1.0D22.625", L=LBYCuS/2, ANGLE= ABYCuS/2, &
            E2= ABYCuS/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBYCuS/2, TILT=PI/2

  BYCuS2a : SBEN, TYPE="@3,1.0D22.625", L=LBYCuS/2, ANGLE=-ABYCuS/2, &
            E1=-ABYCuS/2, E2=0, FINT=0.5, FINTX=0, HGAP=GBYCuS/2, TILT=PI/2
  BYCuS2b : SBEN, TYPE="@3,1.0D22.625", L=LBYCuS/2, ANGLE=-ABYCuS/2, &
            E2=-ABYCuS/2, E1=0, FINT=0, FINTX=0.5, HGAP=GBYCuS/2, TILT=PI/2

! drifts

  LDCuS1  := 17.5
  LDCuS5  := 1.5
  LDCuS6  := 1.0
 dLDCuS3  := 0.0
  LDCuS3  := (16.9693549060454-LDCuS5-LDCuS6)/3 +dLDCuS3
  LDCuS2  := LDCuS3
  LDCuS4  := LDCuS3
  LDCuS7  := 0.3/2
  LDCuS8  := LDCuS6
  LDCuS9  := LDCuS5
  LDCuS10 := LDCuS4
  LDCuS11 := LDCuS3
  LDCuS12 := LDCuS2
  LDCuS13 := LDCuS1

  LDCuS1b  := 0.4781
  LDCuS1a  := LDCuS1-LDCuS1b
  LDCuS2a  := 0.4285
  LDCuS2c  := 0.4781
  LDCuS2b  := LDCuS2-LDCuS2a-LDCuS2c
  LDCuS3a  := 0.4285
  LDCuS3c  := 0.4781
  LDCuS3b  := LDCuS3-LDCuS3a-LDCuS3c
  LDCuS4a  := 0.4285
  LDCuS4c  := 0.1924
  LDCuS4b  := LDCuS4-LDCuS4a-LDCuS4c +(LQR-LQE)/2
  LDCuS5a  := 0.4
  LDCuS5b  := LDCuS5-LDCuS5a +(LQR-LQE)/2
  LDCuS6b  := 0.1924
  LDCuS6a  := LDCuS6-LDCuS6b +(LQR-LQE)/2 -LQE/2-LDCuS7
  LDCuS8a  := 0.4
  LDCuS8b  := LDCuS8-LDCuS8a +(LQR-LQE)/2 -LQE/2-LDCuS7
  LDCuS9b  := 0.1924
  LDCuS9a  := LDCuS9-LDCuS9b +(LQR-LQE)/2
  LDCuS10a := 0.4
  LDCuS10c := 0.4781
  LDCuS10b := LDCuS10-LDCuS10a-LDCuS10c +(LQR-LQE)/2
  LDCuS11a := 0.4285
  LDCuS11c := 0.4781
  LDCuS11b := LDCuS11-LDCuS11a-LDCuS11c
  LDCuS12a := 0.4285
  LDCuS12c := 0.4781
  LDCuS12b := LDCuS12-LDCuS12a-LDCuS12c
  LDCuS13a := 0.4285
  LDCuS13b := LDCuS13-LDCuS13a

  DCuS1a  : DRIF, L=LDCuS1a
  DCuS1b  : DRIF, L=LDCuS1b
  DCuS2a  : DRIF, L=LDCuS2a
  DCuS2b  : DRIF, L=LDCuS2b
  DCuS2c  : DRIF, L=LDCuS2c
  DCuS3a  : DRIF, L=LDCuS3a
  DCuS3b  : DRIF, L=LDCuS3b
  DCuS3c  : DRIF, L=LDCuS3c
  DCuS4a  : DRIF, L=LDCuS4a
  DCuS4b  : DRIF, L=LDCuS4b
  DCuS4c  : DRIF, L=LDCuS4c
  DCuS5a  : DRIF, L=LDCuS5a
  DCuS5b  : DRIF, L=LDCuS5b
  DCuS6a  : DRIF, L=LDCuS6a
  DCuS6b  : DRIF, L=LDCuS6b
  DCuS7   : DRIF, L=LDCuS7
  DCuS8a  : DRIF, L=LDCuS8a
  DCuS8b  : DRIF, L=LDCuS8b
  DCuS9a  : DRIF, L=LDCuS9a
  DCuS9b  : DRIF, L=LDCuS9b
  DCuS10a : DRIF, L=LDCuS10a
  DCuS10b : DRIF, L=LDCuS10b
  DCuS10c : DRIF, L=LDCuS10c
  DCuS11a : DRIF, L=LDCuS11a
  DCuS11b : DRIF, L=LDCuS11b
  DCuS11c : DRIF, L=LDCuS11c
  DCuS12a : DRIF, L=LDCuS12a
  DCuS12b : DRIF, L=LDCuS12b
  DCuS12c : DRIF, L=LDCuS12c
  DCuS13a : DRIF, L=LDCuS13a
  DCuS13b : DRIF, L=LDCuS13b

! markers

  CENCuSXR : MARK !center of CuSXR
  CNTCuS1  : MARK, TYPE="CENTER"
  CNTCuS2  : MARK, TYPE="CENTER"
  CNTCuS3  : MARK, TYPE="CENTER"
  CNTCuS4  : MARK, TYPE="CENTER"

! monitors

  BPMCuS1   : MONI, TYPE="@3,Stripline-5"
  BPMCuS2   : MONI, TYPE="@3,Stripline-5"
  BPMCuS3   : MONI, TYPE="@3,Stripline-5"
  BPMCuS4   : MONI, TYPE="@3,Stripline-2"
  BPMCuS5   : MONI, TYPE="@3,Stripline-2"
  BPMCuS7   : MONI, TYPE="@3,Stripline-2"
  BPMCuS8   : MONI, TYPE="@3,Stripline-5"
  BPMCuS9   : MONI, TYPE="@3,Stripline-5"
  BPMCuS10  : MONI, TYPE="@3,Stripline-5"

! steering correctors

  XCCuS1  : HKIC, TYPE="@3,class-4" !type TBD
  XCCuS4  : HKIC, TYPE="@3,class-4" !type TBD
  XCCuS7  : HKIC, TYPE="@3,class-4" !type TBD
  XCCuS10 : HKIC, TYPE="@3,class-4" !type TBD

  YCCuS2 : VKIC, TYPE="@3,class-4" !type TBD
  YCCuS3 : VKIC, TYPE="@3,class-4" !type TBD
  YCCuS6 : VKIC, TYPE="@3,class-4" !type TBD
  YCCuS8 : VKIC, TYPE="@3,class-4" !type TBD
  YCCuS9 : VKIC, TYPE="@3,class-4" !type TBD

! SROT to remove rotation angle

  AROCuSo := -0.392738235278E-4
  AROCuSi :=  0.622684373434E-16

  ROCuS1 : SROT, ANGLE= AROCuSo
  ROCuS2 : SROT, ANGLE=-AROCuSo
  ROCuS3 : SROT, ANGLE= AROCuSi
  ROCuS4 : SROT, ANGLE=-AROCuSi

! beamlines

  CuSXR : LINE=(SEQ20BEG,BEGCuSXR ,&
                BRCuS1a,BRCuS1b ,CNTCuS1,ROCuS1 ,DCuS1a ,BPMCuS1 ,DCuS1b ,&
                QCuS1  ,QCuS1   ,DCuS2a ,XCCuS1 ,DCuS2b ,BPMCuS2 ,DCuS2c ,&
                QCuS2  ,QCuS2   ,DCuS3a ,YCCuS2 ,DCuS3b ,BPMCuS3 ,DCuS3c ,&
                QCuS3  ,QCuS3   ,DCuS4a ,YCCuS3 ,DCuS4b ,BPMCuS4 ,DCuS4c ,&
                QCuS4  ,QCuS4   ,DCuS5a ,XCCuS4 ,DCuS5b ,&
                BYCuS1a,BYCuS1b ,CNTCuS3,ROCuS3 ,DCuS6a ,BPMCuS5 ,DCuS6b ,&
                QCuS5  ,QCuS5   ,DCuS7  ,CENCuSXR,DCuS7 ,&
                QCuS6  ,QCuS6   ,DCuS8a ,YCCuS6 ,DCuS8b ,ROCuS4  ,&
                BYCuS2a,BYCuS2b ,CNTCuS4,        DCuS9a ,BPMCuS7 ,DCuS9b ,&
                QCuS7  ,QCuS7   ,DCuS10a,XCCuS7 ,DCuS10b,BPMCuS8 ,DCuS10c,&
                QCuS8  ,QCuS8   ,DCuS11a,YCCuS8 ,DCuS11b,BPMCuS9 ,DCuS11c,&
                QCuS9  ,QCuS9   ,DCuS12a,YCCuS9 ,DCuS12b,BPMCuS10,DCuS12c,&
                QCuS10 ,QCuS10  ,DCuS13a,XCCuS10,DCuS13b,ROCuS2  ,&
                BRCuS2a,BRCuS2b ,CNTCuS2,&
                ENDCuSXR,SEQ20END )

  RETURN