TITLE, "LCLS2sc (October 15, 2014)"

! *** OPTICS=LCLS2sc15OCT14 ***

  OPTION, -ECHO, VERIFY, DOUBLE
  ASSIGN, ECHO="LCLS2sc.echo"
  ASSIGN, PRINT="LCLS2sc.print"

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 15-OCT-2014, M. Woodley
!  * shortened inter-linac warm sections ... gun moved 30 m d/s (to Z=20m ...
!    there is now 40 m from present location of CID gun to location of LCLS-II
!    gun)
!  * various cost-cutting changes ... see individual xsif-files
! ------------------------------------------------------------------------------
! 07-AUG-2014, M. Woodley
!  * add emittance measurement in L0-to-laser-heater matching section
!  * laser heater chicane lengthened to reduce R56 to 3.5 mm
!  * collimation systems (COL0, COL1, and COL2) now consist of four 45 degree
!    FODO cells with 3 pairs of collimators separated by 45 degrees (22 m betas
!    at collimators); FODO cell length is 12 m
!  * added a wire scanner at the end of COL0 for "tomographic" emittance
!    measurement
!  * L1 phase advance per cell lowered to 45 degrees
!  * DIAG1 beamline (post-BC1 off-axis diagnostics line) removed
!  * in-line emittance measurement systems incorporated into COL1 and COL2
!  * TCAV(Y), vertical kicker, and lambertson septum added d/s of BC1
!  * change bending direction in BC2 chicane ... toward the aisle
!  * TCAV(Y) added d/s of BC2
!  * EXT FODO cell length doubled, phase advance per cell lowered to 60 degrees
!  * 1.259Q12 quadrupoles replaced by QWs or QEs
!  * BC3 removed
!  * diagnostics complement per "Electron Beam Diagnostics Systems" PRD
!    (LCLSII-2.7-PR-0170)
!  * TYPE attribute of "deprecated" devices is now "decorated" ... see below
! 31-JUL-2014, Y. Nosochkov
!  * implement magnetic kicker with two 2-hole septa in the spreader
!  * remove QBP37 and adjust positions of QBP31, QBP32, QBP35, QBP36
!  * remove unnecessary diagnostics (per J. Frisch)
!  * move TDUNDb 2.8 m d/s, QUM1b 2.0 m d/s, QDL11-QDL19 2.5 m d/s
!    (per J. Stieber)
!  * move markers ENDSXR, BEGDMPS and ENDHXR, BEGDMPH to include
!    RFBSX51 and RFBHX51 into the SXR and HXR areas (per D. Hanquist)
! ------------------------------------------------------------------------------
! 02-MAY-2014, M. Woodley
!  * update 1.3 GHz cryomodule layout (including end caps) per H. Alvarez
!  * update baseline compression setup per P. Emma
!  * remove DIAG1 beamline ... prepare COL1 for inline emittance diagnostics
!  * add "CNT" to list of defined element name prefixes (MARKER element)
!  * add "HOMCM" to list of defined element name prefixes (MARKER element)
! ------------------------------------------------------------------------------
! 31-MAR-2014, M. Woodley
!  * add list of beamline area names (per document LCLSII-2.1-PR-0134)
!  * add list of element name prefixes (per document LCLSII-1.1-TS-0159)
!  * add beamline area boundary MARKer points
! 26-MAR-2014, Y. Nosochkov
!  * put phase shifter and RFBPM positions back to 03/14 version
!  * remove PCTDKIK1,2,3,4 from HXR LTU
! 25-MAR-2014, Y. Nosochkov
!  * add insertable beam stoppers STSP6ha, STSP6hb, STSP6hc in HXR spreader
!  * remove existing BYKIK, TDKIK and SPOILER from HXR LTU
!  * add missing ST60, ST61 stoppers in the BSY
!  * add marker D10Js for location of D10 dump face in SXR line
!  * remove BYKIKb, SPOILERb, TDKIKb, SPOILD2b from SXR
!  * change names: D2b -> STBP33a, ST60b -> STBP33b, ST61b -> STBP33c
! 21-MAR-2014, Y. Nosochkov
!  * update positions of phase shifters and RFBPMs in undulator cells
!  * add Y-corrector to each undulator
!  * update phase shifter parameters (per H-D. Nuhn)
! 14-MAR-2014, Y. Nosochkov
!  * add/update names for area boundary markers
! 07-MAR-2014, Y. Nosochkov
!  * increase main dump length to 1.5 m (to be confirmed)
!  * remove transverse deflecting cavities from SXR dumpline
! 06-MAR-2014, Y. Nosochkov
!  * add a soft bend upstream of the dump bends
!  * roll the dumpline starting from the soft bend by 10 deg
!    to reduce HXR to SXR x-separation at the dumps to ~1.88 m and
!    adjust the vertical position at the dumps
! ------------------------------------------------------------------------------
! 01-MAR-2014, M. Woodley
!  * move cathode 10 m downstream ... now at Z= -10 m
!  * updated cryomodule layout
!    - 11 lambda CM-to-CM spacing
!    - add special short end cap at upstream end of L0
!      > SOL02 -> CAV011 center-to-center = 1.606 m
!    - include L0/L1/L2 feed boxes, L3 vacuum break box, and L3 end box
!      > use XFEL feed and end box lengths (~3.5 m)
!      > use XFEL "string connection box" length (23 lambda) for L3 break box
!  * add DIAG0 diagnostic line and X/Y collimation section after laser heater
!  * add BC3 chicane after dogleg to bypass line
!  * complete XCOR/YCOR/BPM additions in injector and linac areas
! 28-FEB-2014, Y. Nosochkov
!  * update undulators for reduced cell length of 4.4 m, rematch
! 26-FEB-2014, Y. Nosochkov
!  * update magnet types in the spreader, rematch
! 14-FEB-2014, Y. Nosochkov
!  * add a dumpline from the spreader to D10 dump including optics
!    for energy diagnostic
! 17-JAN-2014, Y. Nosochkov
!  * modify HXR spreader from 1-step to 2-step dogleg for tunable R56
!    and better magnet separation
! 18-DEC-2013, Y. Nosochkov
!  * adjust magnet positions in the spreader for less magnet interference
! 18-DEC-2013, M. Woodley
!  * name change: CE11B -> C1XE, CE21B -> C2XE
! 16-DEC-2013, Y. Nosochkov
!  * 3-way spreader design with low R56
! 03-DEC-2013, Y. Nosochkov
!  * make HXR BSY compatible with the existing divergent and biconcave chambers
!  * modify the spreader to reduce R56 and match to the updated BSY
! 21-NOV-2013, Y. Nosochkov
!  * replace the 2-way spreader (TLINE) with a 3-way spreader in BSY
! ------------------------------------------------------------------------------
! 04-NOV-2013, M. Woodley
!  * assign X or Y correctors to cryomodules
!  * redefine linac axis in LI00-LI10 ... modify bypass dogleg geometry
!  * update quadrupole type 1.26Q12 in HXR
!  * laser heater undulator parameters per M. Venturini
!  * latest compression setup per P. Emma
! 26-OCT-2013, Y. Nosochkov
!  * update quadrupole type 1.26Q12 in SXR
!  * update SXR and HXR undulator design, rematch optics
!  * update LTU match
! 21-OCT-2013, M. Woodley
!  * LCLS2sc v1.1
!  * input Twiss from C. Papadopoulos (Parameters_GUN2013_10_08v3.docx) ...
!    use "avg. beta" and "avg. alpha" parameters
!  * everything downstream of QBP13 from Yuri's LCLS2sc_2013_10_16 files
! 15-OCT-2013, M. Woodley
!  * LCLS2sc v1.0
!  * input Twiss from C. Papadopoulos (Parameters_GUN2013_10_08v3.docx)
! 07-OCT-2013, M. Woodley
!  * LCLS2sc v0.1
!  * initial beam parameters from C. Papadopoulos
!  * change 4-quad match to 6-quad match between L0 and laser heater
!  * increase laser heater chicane dispersion to 7.5 cm ... matching requires
!    inner/outer bend separation to increase
!  * increase laser heater chicane inner bend separation by 1.0 m and add an
!    energy collimator
! 06-OCT-2013, M. Woodley
!  * initial bare-bones lattice ... LCLS2sc v0
! 30-SEP-2013, M. Woodley
!  * from XFEL and NGLS designs
! ------------------------------------------------------------------------------

! ==============================================================================
! Deferred/deprecated devices
! ------------------------------------------------------------------------------
! Device TYPE attributes have been prefixed by a 2-character deprecation
! indicator. If the first character of a device's TYPE attribute is not "@" (or
! if a device has no defined TYPE attribute), the device is baseline. If the
! first character of a device's TYPE attribute is "@", the device is deprecated.
! The level of deprecation is indicated by the second character of the TYPE
! attribute:
!
! TYPE="@0..." : level 0 (required but not included)
! TYPE="@1..." : level 1 (not required for CD4 threshold, but required for
!                         minimal machine performance)
! TYPE="@2..." : level 2 (required for CD4 objective performance)
! TYPE="@3..." : level 3 (required for reduced tuning time; not required for
!                         machine performance)
! TYPE="@4..." : level 4 (future machine performance upgrade)
! TYPE="@5..." : level 5 (probably not needed ... leave space in beamline for
!                         future installation)
!
! The remaining characters of TYPE define the device's engineering type.
! ------------------------------------------------------------------------------

! ==============================================================================
! Beamline area names (areas with names in parentheses have not been designed)
! ------------------------------------------------------------------------------
! GUNB  : cathode to L0
! L0B   : L0 (end cap, CM01, end cap, mechanical stay-clear)
! HTR   : laser heater (emittance measurement, chicane, extraction to DIAG0)
! COL0  : collimation 0
! L1B   : L1 (differential pumping, mechanical stay-clear, end cap, CM02-03,
!         HCM01-02, end cap, mechanical stay-clear, differential pumping)
! BC1B  : BC1 chicane
! COL1  : collimation 1 (includes in-line emittance measurement)
! L2B   : L2 (differential pumping, mechanical stay-clear, end cap, CM04-15,
!         end cap, mechanical stay-clear, differential pumping)
! BC2B  : BC2 chicane
! COL2  : collimation 2 (includes in-line emittance measurement)
! L3B   : L3 (differential pumping, mechanical stay-clear, end cap, CM16-25,
!         vacuum break, CM26-23, end cap, mechanical stay-clear, differential
!         pumping)
! EXT   : L3 extension
! DOG   : dogleg to bypass line
! BYP   : bypass line
! SPS   : spreader to SXR
! LTUS  : SXR LTU
! SXX   : SXR extension
! SXR   : SXR undulator
! DMPS  : SXR dump
! SPH   : spreader to HXR
! LTUH  : HXR LTU
! HXR   : HXR undulator
! DMPH  : HXR dump
! SPD   : spreader to BSY dump
! DIAG0 : post laser heater diagnostics line

! ==============================================================================
! Element naming conventions with the first few characters meaning:
! ------------------------------------------------------------------------------
! CAVL.... = 1.3 GHz RF cavity (superconducting)
! CAVC.... = 3.9 GHz RF cavity (superconducting)
! CAVS.... = 2.856 GHz RF structure (warm copper)
! BUN..... = RF buncher (warm)
! TCX..... = transverse deflecting structure (horizontal deflection)
! TCY..... = transverse deflecting structure (vertical deflection)
! BX...... = horizontal bend (split in two (suffixes "a" and "b"))
! BY...... = vertical bend (split in two (suffixes "a" and "b"))
! BR...... = rolled bend (split in two (suffixes "a" and "b"))
! BCX..... = horizontal chicane bend (split in two (suffixes "a" and "b"))
! BLX..... = horizontal Lambertson septum (split in two (suffixes "a" and "b"))
! BLY..... = vertical Lambertson septum (split in two (suffixes "a" and "b"))
! BLR..... = rolled Lambertson septum (split in two (suffixes "a" and "b"))
! BKX..... = horizontal kicker ((split in two (suffixes "a" and "b"))
! BKY..... = vertical kicker (split in two (suffixes "a" and "b"))
! Q....... = quadrupole (normal quad, split in half)
! QCM..... = standard cryomodule quadrupole (normal quad, split in half)
! QSX..... = undulator quadrupole (normal quad, split in half ... SXR)
! QHX..... = undulator quadrupole (normal quad, split in half ... HXR)
! CQ...... = correction quadrupole (normal quad, split in half)
! SQ...... = skew quadrupole (skew quad, split in half)
! SOL..... = solenoid (split in half)
! UM...... = undulator magnet (full undualator segment)
! PS...... = phase shifter undulator
! CX...... = horizontal collimator (vertical jaws, adjustable)
! CY...... = vertical collimator (horizontal jaws, adjustable)
! CE...... = momentum collimator (adjustable)
! PC...... = protection collimator (fixed aperture)
! RO...... = coordinate rotation (non-physical element)
! XC...... = horizontal steering dipole
! XCM..... = standard cryomodule horizontal steering dipole
! YC...... = vertical steering dipole
! YCM..... = standard cryomodule vertical steering dipole
! SC...... = steering coil package (horizontal and vertical dipole correctors)
! BPM..... = beam position monitor (stripline, various resolutions)
! RFB..... = RF beam position monitor (<1 micron rms resolution)
! BPMCM... = standard cryomodule beam position monitor
! WS...... = wire scanner
! YAG..... = YAG screen profile monitor
! OTR..... = optical transition radiation profile monitor
! IM...... = bunch charge monitor (ICT, DCCT, etc.)
! FC...... = Faraday cup
! BZ...... = bunch length monitor (various types)
! BTM..... = burn-through monitor (PPS device)
! PH...... = beam phase detector
! TD...... = tune-up dump (insertable copper block)
! SP...... = beam spoiler
! ST...... = beam stopper
! TR...... = transition radiator
! DUMP.... = beam dump
! BOD..... = beam overlap monitor
! VV...... = vacuum valve (not all valves are in the MAD deck)
! MIR..... = laser insertion mirror
! BLM..... = beam loss monitor (undulator areas)
! CNT..... = ELEGANT centering element
! HOMCM... = standard cryomodule HOM absorber
! ==============================================================================

! constants

  IN2M  : CONSTANT=0.0254          !m/inch
  Cb    : CONSTANT=1.0E10/CLIGHT   !kG-m/GeV
  mc2   : CONSTANT=510.99906E-6    !GeV
  QELEC : CONSTANT=1.602176462E-19 !C

! energy profile

  E0 := 0.75E-3 !NGLS/APEX gun
  Ei := 0.1
  E1 := 0.25
  E2 := 1.6
  Ef := 4.0

  Brho0 := Cb*E0
  Brho1 := Cb*E1
  Brho2 := Cb*E2
  Brhof := Cb*Ef

! compression

  R56HTR := 0.0035 !DXmax = 75 cm
  R56BC1 := 0.055
  R56BC2 := 0.037

  R56CCDLU := 9.99E-5
  R56CCDLD := 9.99E-5

! ------------------------------------------------------------------------------
! select an input beam definition (uncomment the appropriate block below)
! ------------------------------------------------------------------------------

 !COMMENT !C. Papadopoulos (100 pC) ["GUN2013_10_08v3"]
   !Twiss at gun
    BX0 := 2.405573767079E2
    AX0 := 93.366834761206
    BY0 := 2.405573767079E2
    AY0 := 93.366834761206
   !Twiss at S= 15.0 m (ASTRA)
    BXa := 7.54352403513   !"avg. beta"
    AXa := -0.217252127319 !"avg. alpha"
    BYa := 7.54352403513   !"avg. beta"
    AYa := -0.217252127319 !"avg. alpha"
   !Twiss at start of INJ
    BXi := 14.651203071187
    AXi := -1.016805092664
    BYi := 14.651203071188
    AYi := -1.016805092664
   !beam parameters
    QBNCH := 100.0E-12 !pC
    EMITn := 0.45E-06
 !ENDCOMMENT

  COMMENT !C. Papadopoulos (300 pC) ["300pC_2013_10_22_v1_rescaled"]
   !Twiss at gun
    BX0 := 2.971320570657E2
    AX0 := 1.163347713775E2
    BY0 := 2.971320570657E2
    AY0 := 1.163347713775E2
   !Twiss at S= 15.0 m (ASTRA)
    BXa := 10.2489067594  !"avg. beta"
    AXa := -1.32169788895 !"avg. alpha"
    BYa := 10.2489067594  !"avg. beta"
    AYa := -1.32169788895 !"avg. alpha"
   !Twiss at start of INJ
    BXi := 34.364762350834
    AXi := -2.865371555015
    BYi := 34.364762350834
    AYi := -2.865371555015
   !beam parameters
    QBNCH := 300.0E-12 !pC
    EMITn := 0.7E-06
  ENDCOMMENT

  COMMENT !C. Papadopoulos (20 pC) ["20pC_2013_12_04"]
   !Twiss at gun
    BX0 := 8.138732042807E2
    AX0 := 3.139728877282E2
    BY0 := 8.138732042807E2
    AY0 := 3.139728877282E2
   !Twiss at S= 15.0 m (ASTRA)
    BXa := 14.5141571444 !"avg. beta"
    AXa := 1.69345629448 !"avg. alpha"
    BYa := 14.5141571444 !"avg. beta"
    AYa := 1.69345629448 !"avg. alpha"
   !Twiss at start of INJ
    BXi := 3.846974408045
    AXi := 0.158612968692
    BYi := 3.846974408045
    AYi := 0.158612968692
   !beam parameters
    QBNCH := 20.0E-12 !pC
    EMITn := 0.1E-06
  ENDCOMMENT

  TWSS0 : BETA0, ENERGY=E0, BETX=BX0, ALFX=AX0, BETY=BY0, ALFY=AY0
  TWSSa : BETA0, ENERGY=Ei, BETX=BXa, ALFX=AXa, BETY=BYa, ALFY=AYa
  TWSSi : BETA0, ENERGY=Ei, BETX=BXi, ALFX=AXi, BETY=BYi, ALFY=AYi

! ------------------------------------------------------------------------------

! ASTRA beam SIGMA0 definition

  EMITXn := 0.45E-6 !normalized horizontal emittance (m)
  EMITYn := 0.45E-6 !normalized vertical emittance (m)
  BLENG  := 1.02E-3 !rms bunch length (m)
  ESPRD  := 0.05E-2 !rms energy spread (1)

  EMITX := EMITn/(Ei/EMASS)
  EMITY := EMITn/(Ei/EMASS)

  BEAM, PARTICLE=ELECTRON, NPART=QBNCH*QELEC, &
        EX=EMITX, EY=EMITY, SIGT=BLENG, SIGE=ESPRD

  GXa   := (1+AXa*AXa)/BXa
  SIG11 := EMITX*BXa
  SIG21 := -EMITX*AXa
  SIG22 := EMITX*GXa
  C21   := SIG21/SQRT(SIG11*SIG22)
  GYa   := (1+AYa*AYa)/BYa
  SIG33 := EMITY*BYa
  SIG43 := -EMITY*AYa
  SIG44 := EMITY*GYa
  C43   := SIG43/SQRT(SIG33*SIG44)
  SIG0a : SIGMA0, SIGX=SQRT(SIG11), SIGPX=SQRT(SIG22), R21=C21, &
                  SIGY=SQRT(SIG33), SIGPY=SQRT(SIG44), R43=C43, &
                  SIGT=BLENG      , SIGPT=ESPRD

! ------------------------------------------------------------------------------

! beta at WS0H04 waist

  B0H04w := 5.0

! "treaty" Twiss at center of laser heater undulator

  BXlh := 10.0
  AXlh := 0
  BYlh := 10.0
  AYlh := 0

! matched Twiss for coasting linac FODOs

  BXCMfodo1 := 47.726795352478 !L1: 45 degrees per cell
  BYCMfodo1 := 21.372822091582 !L1: 45 degrees per cell
  BXCMfodo2 := 61.479644472161 !L2: 30 degrees per cell
  BYCMfodo2 := 36.272815883187 !L2: 30 degrees per cell
  BXCMfodo3 := 61.479644472161 !L3: 30 degrees per cell
  BYCMfodo3 := 36.272815883187 !L3: 30 degrees per cell

! survey (Z values are w.r.t. start of LI01 where Z=0)

  Xgun  :=    0.28     !beam axis (w.r.t. original linac axis)
  Ygun  :=   -0.99     !beam axis (w.r.t. original linac axis)
  Zgun  :=   20.0      !40 m d/s of location of CID gun (20 m into LI01)
  Za    :=   35.0      !ASTRA treaty point (35 m into LI01)
  Zi    :=   40.759602 !end of L0 (~40.8 m into LI01)
  Zdg0  :=   62.179473 !start of DIAG0 (~62.2 m into LI01)
  Z1beg :=  103.491473 !start of L1 (~1.9 m into LI02)
  Z1end :=  151.538574 !end of L1 (~49.9 m into LI02)
  Z2beg :=  204.701006 !start of L2 (~1.5 m into LI03)
  Z2end :=  362.632995 !end of L2 (~57.8 m into LI04)
  Z3beg :=  460.043393 !start of L3 (~53.6 m into LI05)
  Z3end :=  718.191161 !end of L3 (~7.0 m into LI08)
  Zdog  :=  951.900013 !entrance first dogleg bend (~37.5 m into LI10)
  Xbyp  := -0.65049400 !QBP13 X is |Xbyp| to the south of linac axis
  Ybyp  :=  0.64947800 !QBP13 Y is Ybyp above linac axis
  Zbyp  := 1254.531303 !QBP13 centerline (~35.3 m into LI13)

! ------------------------------------------------------------------------------

! for matching, etc.

! match into bypass dogleg

  BXDLm := 13.154560632507
  AXDLm := -1.349282054806
  BYDLm := 16.059073464302
  AYDLm :=  1.554382739002

! match into LTU emit-diag section in SXR

  BX1 := 46.225914318019
  AX1 := -1.084608326468
  BY1 := 46.225914318019
  AY1 :=  1.084608326468

! initial Twiss for SXR dogleg cells

  MBETXS :=  6.832414283342
  MALFXS := -0.284444919244
  MBETYS := 47.312594187016
  MALFYS :=  2.560928211306

  TWSSms : BETA0, ENERGY=Ef, BETX=MBETXs, ALFX=MALFXs, BETY=MBETYs, ALFY=MALFYs

! periodic Twiss in HXR dogleg cells

  MBETXH := 48.881918697149
  MALFXH :=  3.139871662729
  MBETYH := 96.323795982991
  MALFYH :=  3.616905513764

  TWSSmh : BETA0, ENERGY=Ef, BETX=MBETXh, ALFX=MALFXh, BETY=MBETYh, ALFY=MALFYh

! match into LCLS emittance diagnostic section

  BXEDh := 46.347592421655
  AXEDh := -1.088004889273
  BYEDh := 46.098656017174
  AYEDh :=  1.08081945287

! temporary

  TWSSm : BETA0

! ------------------------------------------------------------------------------

  CALL, FILENAME="common.xsif"
  CALL, FILENAME="CM.xsif"
  CALL, FILENAME="INJ.xsif"
  CALL, FILENAME="DIAG0.xsif"
  CALL, FILENAME="BC1.xsif"
  CALL, FILENAME="BC2.xsif"
  CALL, FILENAME="EXT.xsif"
  CALL, FILENAME="DLBM.xsif"
  CALL, FILENAME="SPRD.xsif"
  CALL, FILENAME="BYP.xsif"
  CALL, FILENAME="LTU.xsif"
  CALL, FILENAME="UND.xsif"

  QBPF : LIST=(QBP13) !upstream half of QBP13

  LCLS2scA : LINE=(ASTRA,DDSCAPb,DCMMSCD,RFB0H00,DCMDPSC,ENDL0B) !from ASTRA
  LCLS2scC : LINE=(HTR,COL0,L1,BC1,COL1,L2,BC2,COL2,L3,EXT,DLBM)
  LCLS2scS : LINE=(BYPASS,BSYLTUsc,SXRUND,DUMPLINEb)
  LCLS2scH : LINE=(FODOLa,SPRDh,SPhBSY,LTU,HXRUND,DUMPLINE)
  LCLS2scD : LINE=(FODOLa,SPRDd)

! ------------------------------------------------------------------------------

! initial BSY coordinates at BEGSP (LTUSPLIT)

  Xf     :=  XOFF
  Yf     :=  1.897939159495
  Zf     := -267.4180504124
  THETAf :=  0
  PHIf   :=  2*AVB
  PSIf   :=  0

! from BEGSP to dump

  BSYLCLS2scS : LINE=(FODOLb,BYPM,BSYLTUsc,SXRUND,DUMPLINEb)
  BSYLCLS2scH : LINE=(SPRDh,SPhBSY,LTU,HXRUND,DUMPLINE)
  BSYLCLS2scD : LINE=(SPRDd)

! ==============================================================================
! COMMANDs
! ------------------------------------------------------------------------------

  SETPLOT, XSIZE=25.4, YSIZE=20.32
  SETPLOT, LWIDTH=5, LSCALE=1.5, SSCALE=1.5, RSCALE=1.5
  OPTION, ECHO

  BEAM, PARTICLE=ELECTRON

! ------------------------------------------------------------------------------

 !CALL, FILENAME="LCLS2sc_match.mad8"
 !CALL, FILENAME="RDB/makeSymbols.mad8"
 !CALL, FILENAME="elegant/makeElegant.mad8"

 !STOP

! ------------------------------------------------------------------------------

! SXR line (linac coordinates)

 !COMMENT
    ASSIGN, PRINT="LCLS2scS.print"
    BEAM, ENERGY=E0
    SET, SETSP, SETSPs
    USE, (GUN,L0,LCLS2scC,LCLS2scS)
    PRINT, FULL
    SURVEY, X0=Xgun, Y0=Ygun, Z0=Zgun, TAPE="LCLS2scS_survey.tape"
    BEAM, ENERGY=Ei
    USE, (LCLS2scA,LCLS2scC,LCLS2scS)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="LCLS2scS_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      STYLE=100, SPLINE, FILE="LCLS2scS", VMIN=0, VMAX=5
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      STYLE=100, SPLINE, FILE="LCLS2scS"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=DX,DY, &
      STYLE=100, SPLINE, FILE="LCLS2scS"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! HXR line (linac coordinates)

 !COMMENT
    ASSIGN, PRINT="LCLS2scH.print"
    BEAM, ENERGY=E0
    SET, SETSP, SETSPh
    USE, (GUN,L0,LCLS2scC,LCLS2scH)
    PRINT, FULL
    SURVEY, X0=Xgun, Y0=Ygun, Z0=Zgun, TAPE="LCLS2scH_survey.tape"
    BEAM, ENERGY=Ei
    USE, (LCLS2scA,LCLS2scC,LCLS2scH)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="LCLS2scH_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      STYLE=100, SPLINE, FILE="LCLS2scH", VMIN=0, VMAX=5
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      STYLE=100, SPLINE, FILE="LCLS2scH"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=DX,DY, &
      STYLE=100, SPLINE, FILE="LCLS2scH"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! BSY dump line (linac coordinates)

 !COMMENT
    ASSIGN, PRINT="LCLS2scD.print"
    BEAM, ENERGY=E0
    SET, SETSP, SETSPd
    USE, (GUN,L0,LCLS2scC,LCLS2scD)
    PRINT, FULL
    SURVEY, X0=Xgun, Y0=Ygun, Z0=Zgun, TAPE="LCLS2scD_survey.tape"
    BEAM, ENERGY=Ei
    USE, (LCLS2scA,LCLS2scC,LCLS2scD)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="LCLS2scD_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      STYLE=100, SPLINE, FILE="LCLS2scD", VMIN=0, VMAX=5
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      STYLE=100, SPLINE, FILE="LCLS2scD"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=DX,DY, &
      STYLE=100, SPLINE, FILE="LCLS2scD"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! DIAG0 diagnostic line (linac coordinates)

 !COMMENT
    ASSIGN, PRINT="DIAG0.print"
    BEAM, ENERGY=E0
    USE, (GUN,L0,HTR,DIAG0)
    PRINT, FULL
    SURVEY, X0=Xgun, Y0=Ygun, Z0=Zgun, TAPE="DIAG0_survey.tape"
    BEAM, ENERGY=Ei
    USE, (LCLS2scA,HTR,DIAG0)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="DIAG0_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      STYLE=100, SPLINE, FILE="DIAG0" !, RANGE=SEQ01END/#E
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=DX,DY, &
      STYLE=100, SPLINE, FILE="DIAG0" !, RANGE=SEQ01END/#E
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! SXR from start of spreader (BSY coordinate system)

 !COMMENT
    ASSIGN, PRINT="BSY-LCLS2scS.print"
    BEAM, ENERGY=Ef
    SET, SETSP, SETSPs
    USE, BSYLCLS2scS
    PRINT, FULL
    SURVEY, X0=Xf, Y0=Yf, Z0=Zf, THETA0=THETAf, PHI0=PHIf, PSI0=PSIf, &
      TAPE="BSY-LCLS2scS_survey.tape"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! HXR from start of spreader (BSY coordinate system)

 !COMMENT
    ASSIGN, PRINT="BSY-LCLS2scH.print"
    BEAM, ENERGY=Ef
    SET, SETSP, SETSPh
    USE, BSYLCLS2scH
    PRINT, FULL
    SURVEY, X0=Xf, Y0=Yf, Z0=Zf, THETA0=THETAf, PHI0=PHIf, PSI0=PSIf, &
      TAPE="BSY-LCLS2scH_survey.tape"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! BSY dump line from start of spreader (BSY coordinate system)

 !COMMENT
    ASSIGN, PRINT="BSY-LCLS2scD.print"
    BEAM, ENERGY=Ef
    SET, SETSP, SETSPd
    USE, BSYLCLS2scD
    PRINT, FULL
    SURVEY, X0=Xf, Y0=Yf, Z0=Zf, THETA0=THETAf, PHI0=PHIf, PSI0=PSIf, &
      TAPE="BSY-LCLS2scD_survey.tape"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! Twiss plots (color)

 !COMMENT
    BEAM, ENERGY=E0
    USE, (GUN,L0)
    PRINT, FULL
    TWISS, COUPLE, BETA0=TWSS0, SAVE
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      TITLE="Gun + L0",&
      COLOUR=100, SPLINE=.F., FILE="LCLS2sc_color", VMIN=0, VMAX=0.12
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      TITLE="Gun + L0",&
      COLOUR=100, SPLINE=.F., FILE="LCLS2sc_color", VMIN=0, VMAX=20
    BEAM, ENERGY=Ei
    SET, SETSP, SETSPs
    USE, (LCLS2scA,LCLS2scC,LCLS2scS)
    TWISS, BETA0=TWSSa, SAVE
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      RANGE=#S/ENDL1B, TITLE="Laser Heater + Coll0 + L1",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=#S/ENDL1B, TITLE="Laser Heater + Coll0 + L1",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=ENDL1B/BEGL2B, TITLE="BC1 + Coll1",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      RANGE=BEGL2B/ENDL2B, TITLE="L2",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      RANGE=BEGL2B/ENDL2B, TITLE="L2",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=ENDL2B/BEGL3B, TITLE="BC2 + Coll2",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      RANGE=BEGL3B/ENDEXT, TITLE="L3 + Extension",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color", VMIN=0, VMAX=5
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      RANGE=BEGL3B/ENDEXT, TITLE="L3 + Extension",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=ENDEXT/MQBP13, TITLE="Dogleg + BC3 + Match to Bypass",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      RANGE=MQBP13/SEQ05END, TITLE="Bypass Line to SPREADER",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ06BEG/SEQ08END, TITLE="SPREADER to SXR Undulator",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ09BEG/#E, TITLE="SXR Undulator to Dump",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    BEAM, ENERGY=Ei
    SET, SETSP, SETSPh
    USE, (LCLS2scA,LCLS2scC,LCLS2scH)
    TWISS, BETA0=TWSSa, SAVE
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ11BEG/SEQ12END, TITLE="SPREADER to HXR Undulator",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ13BEG/#E, TITLE="HXR Undulator to Dump",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    BEAM, ENERGY=Ei
    SET, SETSP, SETSPd
    USE, (LCLS2scA,LCLS2scC,LCLS2scD)
    TWISS, BETA0=TWSSa, SAVE
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ15BEG/#E, TITLE="SPREADER to BSY Dump",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
    BEAM, ENERGY=Ei
    USE, (LCLS2scA,HTR,DIAG0)
    TWISS, BETA0=TWSSa, SAVE
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ16BEG/#E, TITLE="DIAG0",&
      COLOUR=100, SPLINE, FILE="LCLS2sc_color"
 !ENDCOMMENT

! ------------------------------------------------------------------------------

! Twiss plots (black & white)

  COMMENT
    BEAM, ENERGY=E0
    USE, (GUN,L0)
    PRINT, FULL
    TWISS, COUPLE, BETA0=TWSS0, SAVE
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      TITLE="Gun + L0",&
      STYLE=100, SPLINE=.F., FILE="LCLS2sc", VMIN=0, VMAX=0.12
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      TITLE="Gun + L0",&
      STYLE=100, SPLINE=.F., FILE="LCLS2sc", VMIN=0, VMAX=20
    BEAM, ENERGY=Ei
    SET, SETSP, SETSPs
    USE, (LCLS2scA,LCLS2scC,LCLS2scS)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="LCLS2scS_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      RANGE=#S/ENDL1B, TITLE="Laser Heater + Coll0 + L1",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=#S/ENDL1B, TITLE="Laser Heater + Coll0 + L1",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=ENDL1B/BEGL2B, TITLE="BC1 + Coll1",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      RANGE=BEGL2B/ENDL2B, TITLE="L2",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      RANGE=BEGL2B/ENDL2B, TITLE="L2",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=ENDL2B/BEGL3B, TITLE="BC2 + Coll2",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=ENERGY, &
      RANGE=BEGL3B/ENDEXT, TITLE="L3 + Extension",&
      STYLE=100, SPLINE, FILE="LCLS2sc", VMIN=0, VMAX=5
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      RANGE=BEGL3B/ENDEXT, TITLE="L3 + Extension",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=ENDEXT/MQBP13, TITLE="Dogleg + BC3 + Match to Bypass",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS=BETX,BETY, &
      RANGE=MQBP13/SEQ05END, TITLE="Bypass Line to SPREADER",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ06BEG/SEQ08END, TITLE="SPREADER to SXR Undulator",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ09BEG/#E, TITLE="SXR Undulator to Dump",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    BEAM, ENERGY=Ei
    SET, SETSP, SETSPh
    USE, (LCLS2scA,LCLS2scC,LCLS2scH)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="LCLS2scH_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ11BEG/SEQ12END, TITLE="SPREADER to HXR Undulator",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ13BEG/#E, TITLE="HXR Undulator to Dump",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    BEAM, ENERGY=Ei
    SET, SETSP, SETSPd
    USE, (LCLS2scA,LCLS2scC,LCLS2scD)
    TWISS, BETA0=TWSSa, SAVE, TAPE="LCLS2scD_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ15BEG/#E, TITLE="SPREADER to BSY Dump",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
    BEAM, ENERGY=Ei
    USE, (LCLS2scA,HTR,DIAG0)
    PRINT, FULL
    TWISS, BETA0=TWSSa, SAVE, TAPE="DIAG0_twiss.tape"
    PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX,DY, &
      RANGE=SEQ16BEG/#E, TITLE="DIAG0",&
      STYLE=100, SPLINE, FILE="LCLS2sc"
  ENDCOMMENT

! ------------------------------------------------------------------------------

  STOP