
! *** OPTICS=LCLS2sc12DEC14 ***

! LCLS2sc bypass line, plus match to LTU

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 12-DEC-2014, M. Woodley
!  * assign BPM TYPE attributes per PRD LCLSII-2.4-PR-0136
! 09-DEC-2014, Y. Nosochkov
!  * move STBP32 stopper to inside of the SXR spreader chicane and rename it
!    to STSP5s
!  * move D10 dump inside the muon wall in the BSY
!  * add BCS current monitor IMBP28 upstream of the spreader (S. Mao)
!  * add BCS current monitors IMSP1s, IMSP2s upstream of muon wall
!    in SXR (S. Mao)
!  * add BCS collimators PCSP3s, PCSP4s in SPS
! ------------------------------------------------------------------------------
! 28-OCT-2014, M. Woodley
!  * rematch downstream end bypass line (matching subroutine MBYPSP)
!  * set TYPE="fast" for all wire scanners
! ------------------------------------------------------------------------------
! 15-OCT-2014, M. Woodley
!  * rematch downstream end bypass line (matching subroutine MBYPSP)
! 13-OCT-2014, Y. Nosochkov
!  * remove XCBP37, YCBP37 and XCBP33, YCBP33 correctors as redundant
! 10-OCT-2014, Y. Nosochkov
!  * update the TYPE of (4) RFBPMs to indicate the non-baseline level "0"
! 07-AUG-2014, M. Woodley
!  * change "Q2MRK" to "MQBP23" to obey naming convention
!  * restore existing stripline BPMs BPMBP14, BPMPB16, BPMBP18, and BPMBP20;
!    add cavity BPMs near wire scanners
!  * decorate device TYPE attributes to indicate non-baseline status
! 30-JUL-2014, Y. Nosochkov
!  * adjust positions of QBP31, QBP32, QBP35, QBP36 to minimize beta functions
!  * remove quad QBP37
! 22-JUL-2014, Y. Nosochkov
!  * move 4 bypass betatron collimators further downstream
! 02-MAY-2014, M. Woodley
!  * add RWWAKEss MARKER at end of bypass line (for resistive wall wakefield)
! 01-MAY-2014, Y. Nosochkov
!  * replace BPMBP30, BPMBP33 with cavity BPMs RFBBP30, RFBBP33 (per J. Frisch)
! 23-APR-2014, Y. Nosochkov
!  * replace stripline BPMs BPMBP14, BPMBP16, BPMBP18, BPMBP20, BPMBP24,
!    BPMBP35 with cavity BPMs RFBBP14, RFBBP16, RFBBP18, RFBBP20, RFBBP24,
!    RFBBP35 (per J. Frisch)
! 15-APR-2014, Y. Nosochkov
!  * update collimator jaw aperture per LCLSII-2.4-PR-0095
! 09-APR-2014, Y. Nosochkov
!  * add SXR betatron collimators CXBP30, CXBP34
! 07-APR-2014, M. Woodley
!  * reorder some drift length parameter definitions and drift length
!    definitions to avoid using parameters/attributes before they are defined
! 04-APR-2014, Y. Nosochkov
!  * add BCS stopper STBP32 upstream of 3 PPS stoppers in SXR
! ------------------------------------------------------------------------------
! 31-MAR-2014, M. Woodley
!  * element names changed to conform to nomenclature PRD
! 25-MAR-2014, Y. Nosochkov
!  * add marker D10Js for location of D10 dump face in SXR line
!  * remove BYKIKb, SPOILERb, TDKIKb, SPOILD2b
!  * change names: D2b -> STBP33a, ST60b -> STBP33b, ST61b -> STBP33c
! 06-MAR-2014, Y. Nosochkov
!  * minor matching update
! 26-FEB-2014, Y. Nosochkov
!  * rematch to the updated spreader
! 17-JAN-2014, Y. Nosochkov
!  * add QBP36, rematch to the updated spreader
! 18-DEC-2013, Y. Nosochkov
!  * update match to the spreader
! 16-DEC-2013, Y. Nosochkov
!  * match to the updated 3-way spreader with low R56
! 03-DEC-2013, Y. Nosochkov
!  * match to the updated spreader
! 21-NOV-2013, Y. Nosochkov
!  * rematch bypass quads for the 3-way spreader system
! 17-OCT-2013, M. Woodley
!  * merge Yuri's LTU.xsif into BYP.xsif ... this file now defines QBP13
!   (center) to MUWALL
! ------------------------------------------------------------------------------

! ==============================================================================
! dipoles
! ------------------------------------------------------------------------------

! single beam dumper vertical kicker (removed)

  LKIKY := 1.0601 !kicker coil length per magnet (m) [41.737"; SA-380-330-02]

! ==============================================================================
! quadrupoles
! ------------------------------------------------------------------------------

  KQY :=  0.060580505638 !45 degree bypass FODO

  QFY : QUAD, L=LQM/2, TYPE="PEPII", K1= KQY, APER=rQM !dummy magnet
  QDY : QUAD, L=LQM/2, TYPE="PEPII", K1=-KQY, APER=rQM !dummy magnet

  KQBP25 :=  0.072602386503
  KQBP26 := -0.075697882787
  KQBP27 := -0.715551126324E-2
  KQBP35 :=  0.159174938482
  KQBP28 := -0.19588428989
  KQBP36 := -0.116895077863
  KQBP30 := -0.098319263165
  KQBP31 :=  0.149134763485
  KQBP32 := -0.173194658793
  KQBP33 :=  0.15931438685
  KQBP34 :=  KQBP33

  QBP13 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQY,    APER=rQM
  QBP14 : QUAD, TYPE="2Q4",  L=LQM/2, K1=-KQY,    APER=rQM
  QBP15 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQY,    APER=rQM
  QBP16 : QUAD, TYPE="2Q4",  L=LQM/2, K1=-KQY,    APER=rQM
  QBP17 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQY,    APER=rQM
  QBP18 : QUAD, TYPE="2Q4",  L=LQM/2, K1=-KQY,    APER=rQM
  QBP19 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQY,    APER=rQM
  QBP20 : QUAD, TYPE="2Q4",  L=LQM/2, K1=-KQY,    APER=rQM
  QBP21 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQY,    APER=rQM
  QBP22 : QUAD, TYPE="2Q4",  L=LQM/2, K1=-KQY,    APER=rQM
  QBP23 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQY,    APER=rQM
  QBP24 : QUAD, TYPE="2Q4",  L=LQM/2, K1=-KQY,    APER=rQM
  QBP25 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQBP25, APER=rQM
  QBP26 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQBP26, APER=rQM
  QBP27 : QUAD, TYPE="2Q4",  L=LQM/2, K1= KQBP27, APER=rQM
  QBP35 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP35, APER=rQM
  QBP28 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP28, APER=rQM
  QBP36 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP36, APER=rQM
  QBP30 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP30, APER=rQM
  QBP31 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP31, APER=rQM
  QBP32 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP32, APER=rQM
  QBP33 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP33, APER=rQM
  QBP34 : QUAD, TYPE="2Q4W", L=LQM/2, K1= KQBP34, APER=rQM

! ==============================================================================
! drifts
! ------------------------------------------------------------------------------

  LCM2a  := 31.2135115 !places upstream face of muon wall at proper z-location

! bypass drifts which locate BPMs, XCORs, YCORs, WSs, and collimators w.r.t.
! bypass line "2Q4" QUADs

! DCY   : 1/2 dist. between bypass quads - from PEP-II deck
! DCYc  : corrects distance between QBP30 and QBP31

  DCY   : DRIF, L=(101.6-LQM)/2
  DCYi  : DRIF, L=0.8
  DCYc  : DRIF, L=53.40728-DCYi[L]-Lcoll
  DCYca : DRIF, L=6.0
  DCYcb : DRIF, L=DCYc[L]-DCYca[L]-LPCSP
  DCYd  : DRIF, L=DCY[L]-35.269103
 dDCYe  := -29.3 !adjust position of QBP31
  DCYe  : DRIF, L=35.269103-0.6096 +dDCYe
 dDCYf  := 0.0 !adjust Z at BSYENDb
 dDCYg  := 0.0 !adjust position of QBP36
  DCYf  : DRIF, L=3.795346060085 +dDCYf-dDCYg
  DCYg  : DRIF, L=4.7184 +dDCYg

! DCM1b : separates QBP31 from QBP32
! DCM2a+DCM2b : separates QBP32 from the face of D10
! DCM2c : separates STBP33a from STBP33b (center-to-center)
! DCM2d : separates center of STBP33b from QBP33
! DCM2e : separates the face of D10 from center of STBP33a
! DCM3a : separates QBP33 from STBP33c
! DCM3b+DCM3c+2*DDL1C : separates STBP33c from QBP34
! DCM3d+DCWLa+DCWLb+Lcoll : separates QBP34 from MUWALL

  DDL1c : DRIF, L=0.609226+1.0601/2
  DCM1b : DRIF, L=58.22939075-3.048
  DCM2a : DRIF, L=LCM2a+3.6576
  DCM2b : DRIF, L=295.3*IN2M -DCM2e[L]
  DCM2c : DRIF, L=59.0*IN2M
  DCM2d : DRIF, L=59.1*IN2M-LQM/2 +1.2192
  DCM2e : DRIF, L=4.201207
  DCM3a : DRIF, L=215.9*IN2M-LQM/2-1.2192
  DCM3b : DRIF, L=80.0*IN2M-DDL1C[L]
  DCM3c : DRIF, L=286.8*IN2M-DDL1C[L]-LQM/2-2.032
  DCM3d : DRIF, L=41.8*IN2M-LQM/2+2.032
  DCWLb : DRIF, L=1.0
  DCWLc : DRIF, L=0.8
  DCWLa : DRIF, L=7.93496-DCWLb[L]-DCWLc[L]-Lcoll-LPCSP

! D2Q4a : QUAD to BPM
! D2Q4b : BPM to XCOR
! D2Q4c : XCOR to YCOR
! D2Q4d : a+b+c+d=DCY
! D2Q4e : YCOR to collimator
! D2Q4f : a+b+c+e+Lcoll+f=DCY
! D2Q4g : collimator to wire scanner
! D2Q4h : g+h=f
! D2Q4i : YCOR to wire scanner
! D2Q4j : i+j=d
! D2Q4k : locates WSBP3
! D2Q4l : a+b+c+l=DCM1b
! D2Q4m : a+b+c+l=DCM2a
! D2Q4n : a+b+c+l=DCM3a
! D2Q4o : a+b+c+o=DCM3d

  D2Q4a  : DRIF, L=0.4598
  D2Q4b  : DRIF, L=0.7433
  D2Q4c  : DRIF, L=0.2794
  D2Q4d  : DRIF, L=DCY[L]-(D2Q4a[L]+D2Q4b[L]+D2Q4c[L])
  D2Q4e  : DRIF, L=1.26
  D2Q4f  : DRIF, L=D2Q4d[L]-(D2Q4e[L]+Lcoll)
  D2Q4h  : DRIF, L=2.4
  D2Q4g  : DRIF, L=D2Q4f[L]-D2Q4h[L]
  D2Q4g2 : DRIF, L=0.1
  D2Q4g1 : DRIF, L=D2Q4g[L]-D2Q4g2[L]
  D2Q4j  : DRIF, L=1.0
  D2Q4i  : DRIF, L=D2Q4d[L]-D2Q4j[L]
  D2Q4i2 : DRIF, L=0.1
  D2Q4i1 : DRIF, L=D2Q4i[L]-D2Q4i2[L]
  D2Q4k  : DRIF, L=2.0
 dD2Q4l  := -19.8 !adjust position of QPB32
  D2Q4l  : DRIF, L=DCM1b[L]-(D2Q4a[L]+D2Q4b[L]+D2Q4c[L]) -dDCYe +dD2Q4l
  D2Q4m  : DRIF, L=DCM2a[L]-(D2Q4a[L]+D2Q4b[L]+D2Q4c[L]) -dD2Q4l
  D2Q4ma : DRIF, L=1.0
  D2Q4mb : DRIF, L=D2Q4m[L]-D2Q4ma[L]
  D2Q4n  : DRIF, L=DCM3a[L]-(D2Q4a[L]+D2Q4b[L]+D2Q4c[L])
  D2Q4o  : DRIF, L=DCM3d[L]-(D2Q4a[L]+D2Q4b[L]+D2Q4c[L])
  D2Q4q  : DRIF, L=0.5
  D2Q4s  : DRIF, L=D2Q4d[L]-LQM/2 +35.0 -36.0
  D2Q4t  : DRIF, L=D2Q4d[L]-LQM/2 -35.0 +36.0
  D2Q4tb : DRIF, L=1.0
  D2Q4ta : DRIF, L=D2Q4t[L]-D2Q4tb[L]

! ==============================================================================
! collimators
! ------------------------------------------------------------------------------

  CYBP20 : RCOL, L=Lcoll, YSIZE= 8.7E-3, XSIZE=20E-3
  CYBP24 : RCOL, L=Lcoll, YSIZE= 8.7E-3, XSIZE=20E-3

  CXBP21 : RCOL, L=Lcoll, XSIZE=14.1E-3, YSIZE=20E-3
  CXBP25 : RCOL, L=Lcoll, XSIZE=14.1E-3, YSIZE=20E-3

  CXBP30 : RCOL, L=Lcoll, XSIZE=4.3E-3, YSIZE=20E-3
  CXBP34 : RCOL, L=Lcoll, XSIZE=7.8E-3, YSIZE=20E-3

! ==============================================================================
! BPMs
! ------------------------------------------------------------------------------

  BPMBP13 : MONI, TYPE="Stripline-5"
  BPMBP14 : MONI, TYPE="Stripline-5"
  BPMBP15 : MONI, TYPE="Stripline-5"
  BPMBP16 : MONI, TYPE="Stripline-5"
  BPMBP17 : MONI, TYPE="Stripline-5"
  BPMBP18 : MONI, TYPE="Stripline-5"
  BPMBP19 : MONI, TYPE="Stripline-5"
  BPMBP20 : MONI, TYPE="Stripline-5"
  BPMBP21 : MONI, TYPE="Stripline-5"
  BPMBP22 : MONI, TYPE="Stripline-5"
  BPMBP23 : MONI, TYPE="Stripline-5" !2/22/11
  BPMBP25 : MONI, TYPE="Stripline-5" !2/22/11
  BPMBP26 : MONI, TYPE="Stripline-5" !2/22/11
  BPMBP27 : MONI, TYPE="Stripline-5" !2/22/11
  BPMBP28 : MONI, TYPE="Stripline-5" !2/22/11
  BPMBP36 : MONI, TYPE="Stripline-5"
  BPMBP31 : MONI, TYPE="Stripline-5"
  BPMBP32 : MONI, TYPE="Stripline-5"
  BPMBP34 : MONI, TYPE="Stripline-5"

  RFBWSBP1 : MONI, TYPE="@2,CavityS-1"
  RFBWSBP2 : MONI, TYPE="@2,CavityS-1"
  RFBWSBP3 : MONI, TYPE="@2,CavityS-1"
  RFBWSBP4 : MONI, TYPE="@2,CavityS-1"
  RFBBP24  : MONI, TYPE="@2,CavityS-1" !4/23/14
  RFBBP35  : MONI, TYPE="@2,CavityS-1" !4/23/14
  RFBBP30  : MONI, TYPE="@2,CavityS-1"
  RFBBP33  : MONI, TYPE="@2,CavityS-1"

! ==============================================================================
! XCORs
! ------------------------------------------------------------------------------

  XCBP13 : HKIC, TYPE="Bypass"
  XCBP14 : HKIC, TYPE="Bypass"
  XCBP15 : HKIC, TYPE="Bypass"
  XCBP16 : HKIC, TYPE="Bypass"
  XCBP17 : HKIC, TYPE="Bypass"
  XCBP18 : HKIC, TYPE="Bypass"
  XCBP19 : HKIC, TYPE="Bypass"
  XCBP20 : HKIC, TYPE="Bypass"
  XCBP21 : HKIC, TYPE="Bypass"
  XCBP22 : HKIC, TYPE="Bypass"
  XCBP23 : HKIC, TYPE="type-4" !2/22/11
  XCBP24 : HKIC, TYPE="Bypass#2" !4/18/13
  XCBP25 : HKIC, TYPE="Bypass#2" !4/18/13
  XCBP26 : HKIC, TYPE="Bypass#2" !4/18/13
  XCBP27 : HKIC, TYPE="Bypass#2" !4/18/13
  XCBP35 : HKIC, TYPE="Bypass#2" !10/1/13
  XCBP28 : HKIC, TYPE="Bypass#2" !4/18/13
 !XCBP36 : HKIC, TYPE="Bypass"   !remove
  XCBP30 : HKIC, TYPE="Bypass"
  XCBP31 : HKIC, TYPE="Bypass"
  XCBP32 : HKIC, TYPE="Bypass"
 !XCBP33 : HKIC, TYPE="Bypass"   !remove
  XCBP34 : HKIC, TYPE="Bypass"

! ==============================================================================
! YCORs
! ------------------------------------------------------------------------------

  YCBP13 : VKIC, TYPE="Bypass"
  YCBP14 : VKIC, TYPE="Bypass"
  YCBP15 : VKIC, TYPE="Bypass"
  YCBP16 : VKIC, TYPE="Bypass"
  YCBP17 : VKIC, TYPE="Bypass"
  YCBP18 : VKIC, TYPE="Bypass"
  YCBP19 : VKIC, TYPE="Bypass"
  YCBP20 : VKIC, TYPE="Bypass"
  YCBP21 : VKIC, TYPE="Bypass"
  YCBP22 : VKIC, TYPE="Bypass"
  YCBP23 : VKIC, TYPE="type-4" !2/22/11
  YCBP24 : VKIC, TYPE="Bypass#2" !4/18/13
  YCBP25 : VKIC, TYPE="Bypass#2" !4/18/13
  YCBP26 : VKIC, TYPE="Bypass#2" !4/18/13
  YCBP27 : VKIC, TYPE="Bypass#2" !4/18/13
  YCBP35 : VKIC, TYPE="Bypass#2" !10/1/13
  YCBP28 : VKIC, TYPE="Bypass#2" !4/18/13
 !YCBP36 : VKIC, TYPE="Bypass"   !remove
  YCBP30 : VKIC, TYPE="Bypass"
  YCBP31 : VKIC, TYPE="Bypass"
  YCBP32 : VKIC, TYPE="Bypass"
 !YCBP33 : VKIC, TYPE="Bypass"   !remove
  YCBP34 : VKIC, TYPE="Bypass"

! ==============================================================================
! diagnostics, etc.
! ------------------------------------------------------------------------------

  WSBP1 : WIRE, TYPE="fast"
  WSBP2 : WIRE, TYPE="fast"
  WSBP3 : WIRE, TYPE="fast"
  WSBP4 : WIRE, TYPE="fast"

  STBP33a : INST !center of STBP33a PPS stopper
  STBP33b : INST !STBP33a 1st backup PPS stopper
  STBP33c : INST !STBP33a 2nd backup PPS stopper

  IMBP28 : IMON !BCS average current monitor u/s of the spreader
  IMSP1s : IMON !BCS average current monitor in SPS
  IMSP2s : IMON !BCS average current monitor in SPS

  PCSP3s : ECOL, L=LPCSP !BCS protection collimator in SPS (size TBD)
  PCSP4s : ECOL, L=LPCSP !BCS protection collimator in SPS (size TBD)

! ==============================================================================
! MARKER points
! ------------------------------------------------------------------------------

! MQBP23 : QBP23 (Q285330T) quad center (Z=2270.531303)
! S100B  : Station-100B is same Z as Station-100, but off axis in X & Y

  MQBP23   : MARK
  S100B    : MARK
  RWWAKE4  : MARK, TYPE="WAKE" !bypass line beampipe wake applied here
  LTUSPLIT : MARK !SXR/HXR/D10 split point

! ==============================================================================
! BEAMLINEs
! ------------------------------------------------------------------------------

  FODO : LINE=(QFY,DCY,DCY,QDY,QDY,DCY,DCY,QFY)

  FODOLa : LINE=(&
          QBP13,D2Q4a,BPMBP13,D2Q4b,XCBP13,D2Q4c,YCBP13,D2Q4d,DCY,&
    QBP14,QBP14,D2Q4a,BPMBP14,D2Q4b,XCBP14,D2Q4c,YCBP14,D2Q4i1,&
      RFBWSBP1,D2Q4i2,WSBP1,D2Q4j,DCY,&
    QBP15,QBP15,D2Q4a,BPMBP15,D2Q4b,XCBP15,D2Q4c,YCBP15,D2Q4d,DCY,&
    QBP16,QBP16,D2Q4a,BPMBP16,D2Q4b,XCBP16,D2Q4c,YCBP16,D2Q4i1,&
      RFBWSBP2,D2Q4i2,WSBP2,D2Q4j,DCY,&
    QBP17,QBP17,D2Q4a,BPMBP17,D2Q4b,XCBP17,D2Q4c,YCBP17,D2Q4d,DCY,&
    QBP18,QBP18,D2Q4a,BPMBP18,D2Q4b,XCBP18,D2Q4c,YCBP18,D2Q4i1,&
      RFBWSBP3,D2Q4i2,WSBP3,D2Q4j,DCY,&
    QBP19,QBP19,D2Q4a,BPMBP19,D2Q4b,XCBP19,D2Q4c,YCBP19,D2Q4d,DCY,&
    QBP20,QBP20,D2Q4a,BPMBP20,D2Q4b,XCBP20,D2Q4c,YCBP20,D2Q4e,&
      CYBP20,D2Q4g1,RFBWSBP4,D2Q4g2,WSBP4,D2Q4h,DCY,&
    QBP21,QBP21,D2Q4a,BPMBP21,D2Q4b,XCBP21,D2Q4c,YCBP21,D2Q4e,&
      CXBP21,D2Q4f,DCY,&
    QBP22,QBP22,D2Q4a,BPMBP22,D2Q4b,XCBP22,D2Q4c,YCBP22,D2Q4d,DCY,&
    QBP23,MQBP23,QBP23,D2Q4a,BPMBP23,D2Q4b,XCBP23,D2Q4c,YCBP23,D2Q4d,DCY,&
    QBP24,QBP24,D2Q4a,RFBBP24,D2Q4b,XCBP24,D2Q4c,YCBP24,D2Q4e,&
      CYBP24,D2Q4f,DCY,&
    QBP25,QBP25,D2Q4a,BPMBP25,D2Q4b,XCBP25,D2Q4c,YCBP25,D2Q4e,&
      CXBP25,D2Q4f,DCY,&
    QBP26,QBP26,D2Q4a,BPMBP26,D2Q4b,XCBP26,D2Q4c,YCBP26,D2Q4d,DCY,&
    QBP27,QBP27,D2Q4a,BPMBP27,D2Q4b,XCBP27,D2Q4c,YCBP27,D2Q4s,&
    QBP35,QBP35,D2Q4a,RFBBP35,D2Q4b,XCBP35,D2Q4c,YCBP35,D2Q4ta,IMBP28,D2Q4tb,&
    QBP28,QBP28,D2Q4a,BPMBP28,D2Q4b,XCBP28,D2Q4c,YCBP28,D2Q4q,&
    ENDBYP,RWWAKE4,&
    LTUSPLIT,&
    SEQ05END)

  FODOLb : LINE=(&
    SPRDs,DCYf,&
    QBP36,QBP36,D2Q4a,BPMBP36,D2Q4b,       D2Q4c,       DCYg,&
    QBP30,QBP30,D2Q4a,RFBBP30,D2Q4b,XCBP30,D2Q4c,YCBP30,DCYi,CXBP30,&
                DCYca,PCSP3s,DCYcb)

  FODOL : LINE=(FODOLa,FODOLb)

  BYPM : LINE=(DCYd,S100B,DCYe,&
    QBP31,QBP31,D2Q4a,BPMBP31,D2Q4b,XCBP31,D2Q4c,YCBP31,D2Q4l,&
    QBP32,QBP32,D2Q4a,BPMBP32,D2Q4b,XCBP32,D2Q4c,YCBP32,D2Q4ma,IMSP1s,D2Q4mb,&
      DCM2b,DCM2e,STBP33a,DCM2c,STBP33b,DCM2d,&
    QBP33,QBP33,D2Q4a,RFBBP33,D2Q4b,       D2Q4c,       D2Q4n,&
      STBP33c,DCM3b,DDL1C,DDL1C,DCM3c,&
    QBP34,QBP34,D2Q4a,BPMBP34,D2Q4b,XCBP34,D2Q4c,YCBP34,D2Q4o,IMSP2s,&
      DCWLa,PCSP4s,DCWLb,CXBP34,DCWLc)

  BYPASS : LINE=(FODOL,BYPM)

! ------------------------------------------------------------------------------

  RETURN
