! *** OPTICS=LCLS2sc31MAR14 ***

! LCLS2sc bunch compressor chicane #1

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 31-MAR-2014, M. Woodley
!  * replace chromatic BC1/DIAG1/COL1 match with BC1/COL1 non-chromatic match
!  * element names changed to conform to nomenclature PRD
! ------------------------------------------------------------------------------
! 14-JAN-2014, M. Woodley
!  * change BC1 dipole names from "BX1*" to "BXC1*"
! ------------------------------------------------------------------------------
! 16-OCT-2013, M. Woodley
!  * change BC1 dipole TYPE from "5D7.1" to "1.69D6.28T" ... no change in
!    physical parameters
! ------------------------------------------------------------------------------

! ==============================================================================
! SBEN
! ------------------------------------------------------------------------------

! BC1 chicane
! - approximate on-axis effective length per R. Carr (01-AUG-05 PE)
! - use series approximation for sinc(x)=sin(x)/x to allow BXh=0

! Brho1 : beam rigidity at chicane (kG-m)
! GB1   : 1.69D6.28T gap height (m)
! ZB1   : 1.69D6.28T "Z" length (m)
! BB1   : chicane bend field (kG) for R56= 0.055 m @ 250 MeV
! AB1   : chicane bend angle (rad)
! LB1   : chicane bend path length (m)
! AB1S  : "short" half chicane bend angle (rad)
! LB1S  : "short" half chicane bend path length (m)
! AB1L  : "long" half chicane bend angle (rad)
! LB1L  : "long" half chicane bend path length (m)

  Brho1    := Cb*E1
  GB1      := 0.04328
  ZB1      := 0.2032
  BB1      := -4.210954630724 !R56=0.055
  ARG1     := ZB1*BB1/Brho1
  AB1      := ASIN(ARG1)
  AB1_2    := AB1*AB1
  AB1_4    := AB1_2*AB1_2
  AB1_6    := AB1_4*AB1_2
  SINCAB1  := 1-AB1_2/6+AB1_4/120-AB1_6/5040 !~sinc(AB1)=sin(AB1)/AB1
  LB1      := ZB1/SINCAB1
  AB1S     := ASIN(ARG1/2)
  AB1S_2   := AB1S*AB1S
  AB1S_4   := AB1S_2*AB1S_2
  AB1S_6   := AB1S_4*AB1S_2
  SINCAB1S := 1-AB1S_2/6+AB1S_4/120-AB1S_6/5040 !~sinc(AB1S)=sin(AB1S)/AB1S
  LB1S     := ZB1/(2*SINCAB1S)
  AB1L     := AB1-AB1S
  LB1L     := LB1-LB1S

! BCX11 gets an offset of 2.2 mm (theta*L/8) towards the wall
! BCX12 gets an offset of 2.2 mm (theta*L/8) towards the aisle
! BCX13 gets an offset of 2.2 mm (theta*L/8) towards the aisle
! BCX14 gets an offset of 2.2 mm (theta*L/8) towards the wall

  BCX11A : SBEN, TYPE="1.69D6.28T", L=LB1S, ANGLE=+AB1S, HGAP=GB1/2, &
                 E1=0, FINT=0.387, FINTX=0
  BCX11B : SBEN, TYPE="1.69D6.28T", L=LB1L, ANGLE=+AB1L, HGAP=GB1/2, &
                 FINT=0, E2=+AB1, FINTX=0.387
  BCX12A : SBEN, TYPE="1.69D6.28T", L=LB1L, ANGLE=-AB1L, HGAP=GB1/2, &
                 E1=-AB1, FINT=0.387, FINTX=0
  BCX12B : SBEN, TYPE="1.69D6.28T", L=LB1S, ANGLE=-AB1S, HGAP=GB1/2, &
                 FINT=0, E2=0, FINTX=0.387
  BCX13A : SBEN, TYPE="1.69D6.28T", L=LB1S, ANGLE=-AB1S, HGAP=GB1/2, &
                 E1=0, FINT=0.387, FINTX=0
  BCX13B : SBEN, TYPE="1.69D6.28T", L=LB1L, ANGLE=-AB1L, HGAP=GB1/2, &
                 FINT=0, E2=-AB1, FINTX=0.387
  BCX14A : SBEN, TYPE="1.69D6.28T", L=LB1L, ANGLE=+AB1L, HGAP=GB1/2, &
                 E1=+AB1, FINT=0.387, FINTX=0
  BCX14B : SBEN, TYPE="1.69D6.28T", L=LB1S, ANGLE=+AB1S, HGAP=GB1/2, &
                 FINT=0, E2=0, FINTX=0.387

! ==============================================================================
! QUAD
! ------------------------------------------------------------------------------

! L1 to BC1 chicane

  KQ1C01 :=  0.9272171 !0.928518791822

  Q1C01 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQ1C01

! BC1 chicane

  KCQ11 := 0
  KCQ12 := 0

  CQ11B : QUAD, TYPE="2.362Q3.5", L=LQc/2, APER=rQc, K1=KCQ11
  CQ12B : QUAD, TYPE="2.362Q3.5", L=LQc/2, APER=rQc, K1=KCQ12

! NOTE: there are two BC1/DIAG1/COL1 matching configurations:
! - "non-chromatic" is matched to COL1, but is NOT matched to DIAG1 ... this
!   configuration has good chromatic properties for S2E tracking studies
! - "DIAG1 match" is matched both to DIAG1 and to COLL1, but will have large
!   chromatic emittance growth (>50%) from some of the quadrupoles ... this
!   configuration requires further development

!            non-chromatic      DIAG1 match
!           ---------------  ----------------
  KQCD11 := -0.6            ! -1.995320553438
  KQCD12 :=  1.98171796731  !  6.211555632054
  KQCD13 :=  0.0            !-10.171942060243
  KQCD14 :=  0.0            !  4.664353983162
  KQDC11 :=  0.0            !  3.038723245646 !"Collins" quadrupole
  KQDC12 := -1.47985034653  !  3.006905880726
  KQDC13 :=  2.306228521213 ! -2.298150687493
  KQC101 := -2.055401832949 ! -1.630770758414 !-KQColl1

! BC1 chicane to DIAG1 and COL1

  QCD11 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQCD11
  QCD12 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQCD12
  QCD13 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQCD13
  QCD14 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQCD14
  QDC11 : QUAD, TYPE="1.0Q3.1",   L=LQs/2, APER=rQs, K1=KQDC11
  QDC12 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQDC12
  QDC13 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQDC13

! COL1 collimation section

  KQColl1 := 1.631665309433

  QFColl1 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1= KQColl1
  QDColl1 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=-KQColl1

  KQC102 :=  KQColl1
  KQC103 := -KQColl1
  KQC104 :=  1.176351116268
  KQC105 := -1.059888734274
  KQC106 :=  0.696637522161

  QC101 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQC101
  QC102 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQC102
  QC103 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQC103
  QC104 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQC104
  QC105 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQC105
  QC106 : QUAD, TYPE="1.259Q3.5", L=LQx/2, APER=rQx, K1=KQC106

! ==============================================================================
! DRIF
! ------------------------------------------------------------------------------

! L1 to BC1 chicane

  D1C00 : DRIF, L=1.431674963539
  D1C01 : DRIF, L=0.25

  D1C00b  : DRIF, L=0.15
  D1C00a  : DRIF, L=D1C00[L]-D1C00b[L]

! BC1 chicane

  ZDC1o  := 2.6381-ZB1            !BCX11 exit to BCX12 entrance
  ZDC1oa := 0.3                   !BCX11 exit to CQ11B center
  ZDC1ob := 1.4                   !CQ11B center to YCM12B center
  ZDC1oc := ZDC1o-(ZDC1oa+ZDC1ob) !YCM12B center to BCX12 entrance
  ZDC1od := ZDC1o-ZDC1oa          !CQ11B center to BCX12 entrance
  ZDC1oe := 0.3                   !BCX11 exit to CQ11B center

  DC1o  : DRIF, L=ZDC1o/COS(AB1), TYPE="CSR"
  DC1oa : DRIF, L=ZDC1oa/COS(AB1)-LQc/2, TYPE="CSR"
  DC1ob : DRIF, L=ZDC1ob/COS(AB1)-LQc/2, TYPE="CSR"
  DC1oc : DRIF, L=ZDC1oc/COS(AB1), TYPE="CSR"
  DC1i  : DRIF, L=0.8302, TYPE="CSR"
  DC1ia : DRIF, L=0.24864, TYPE="CSR"
  DC1ib : DRIF, L=0.16446, TYPE="CSR"
  DC1ic : DRIF, L=0.182606, TYPE="CSR"
  DC1id : DRIF, L=0.234494, TYPE="CSR"
  DC1od : DRIF, L=ZDC1od/COS(AB1)-LQc/2, TYPE="CSR"
  DC1oe : DRIF, L=ZDC1oe/COS(AB1)-LQc/2, TYPE="CSR"

! BC1 chicane to diagnostic line

  DCD10 : DRIF, L=0.25
  DCD11 : DRIF, L=6.6
  DCD12 : DRIF, L=0.6
  DCD13 : DRIF, L=0.5
  DCD14 : DRIF, L=0.25

  DCD10a  : DRIF, L=DCD10[L]/2
  DCD10b  : DRIF, L=DCD10[L]-DCD10a[L]
  DCD11a  : DRIF, L=0.15
  DCD11b  : DRIF, L=DCD11[L]-DCD11a[L]
  DCD12a  : DRIF, L=DCD12[L]/2
  DCD12b  : DRIF, L=DCD12[L]-DCD12a[L]
  DCD14a  : DRIF, L=DCD14[L]/2
  DCD14b  : DRIF, L=DCD14[L]-DCD14a[L]

! COL1 collimation section

  DColl1  : DRIF, L=7.953376144668
  DColl1a : DRIF, L=0.2
  DColl1c : DRIF, L=0.5
  DColl1b : DRIF, L=DColl1[L]-DColl1a[L]-DColl1c[L]

  DKYDG1a : DRIF, L=0.4999991139 !u/s half of BKYDG1
  DKYDG1b : DRIF, L=0.4999937972 !d/s half of BKYDG1
  DDC10   : DRIF, L=4.9188
  DDC11   : DRIF, L=1.0974
  DDC12   : DRIF, L=1.45
  DDC13   : DRIF, L=0.5
  DDC14   : DRIF, L=10.0
  DDC15   : DRIF, L=10.0
  DDC16   : DRIF, L=0.5

  DDC11a  : DRIF, L=DDC11[L]/2
  DDC11b  : DRIF, L=DDC11[L]-DDC11a[L]
  DDC12b  : DRIF, L=0.5
  DDC12a  : DRIF, L=DDC12[L]-DDC12b[L]
  DDC14a  : DRIF, L=0.2
  DDC14b  : DRIF, L=DDC14[L]-DDC14a[L]
  DDC15a  : DRIF, L=0.2
  DDC15b  : DRIF, L=DDC15[L]-DDC15a[L]
  DDC16a  : DRIF, L=0.15
  DDC16b  : DRIF, L=DDC16[L]-DDC16a[L]

! ==============================================================================
! BPMs
! ------------------------------------------------------------------------------

  BPM1C01 : MONI, TYPE="10_um_res_R45"
  BPMS11B : MONI, TYPE="20_um_res"
  BPMCD11 : MONI, TYPE="10_um_res_R45"
  BPMCD12 : MONI, TYPE="10_um_res_R45"
  BPMCD13 : MONI, TYPE="10_um_res_R45"
  BPMCD14 : MONI, TYPE="10_um_res_R45"
  BPMDC11 : MONI, TYPE="10_um_res_R45"
  BPMDC12 : MONI, TYPE="10_um_res_R45"
  BPMDC13 : MONI, TYPE="10_um_res_R45"
  BPMC101 : MONI, TYPE="10_um_res_R45"
  BPMC102 : MONI, TYPE="10_um_res_R45"
  BPMC103 : MONI, TYPE="10_um_res_R45"
  BPMC104 : MONI, TYPE="10_um_res_R45"
  BPMC105 : MONI, TYPE="10_um_res_R45"
  BPMC106 : MONI, TYPE="10_um_res_R45"

! ==============================================================================
! XCORs
! ------------------------------------------------------------------------------

  XC1C00 : HKIC, TYPE="class-1a"
  XCCD11 : HKIC, TYPE="class-1a"
  XCCD12 : HKIC, TYPE="class-1a"
  XCDC11 : HKIC, TYPE="class-1a"
  XCC102 : HKIC, TYPE="class-6"
  XCC104 : HKIC, TYPE="class-6"
  XCC106 : HKIC, TYPE="class-1a"

! ==============================================================================
! YCORs
! ------------------------------------------------------------------------------

  YC1C00 : VKIC, TYPE="class-1a"
  YCM12B : VKIC, TYPE="class-6"
  YCCD11 : VKIC, TYPE="class-1a"
  YCCD12 : VKIC, TYPE="class-1a"
  YCC101 : VKIC, TYPE="class-6"
  YCC103 : VKIC, TYPE="class-6"
  YCC105 : VKIC, TYPE="class-6"
  YCC106 : VKIC, TYPE="class-1a"

! ==============================================================================
! marker points, etc.
! ------------------------------------------------------------------------------

! collimators

  CEBC1 : RCOL, L=0 !movable BC1 X jaw energy collimator
  CY11  : RCOL, L=0 !Y betatron collimator
  CX11  : RCOL, L=0 !X betatron collimator
  CY12  : RCOL, L=0 !Y betatron collimator
  CX12  : RCOL, L=0 !X betatron collimator

! instruments

  OTR11B : PROF, TYPE="OTR" !BC1 energy spread
  BZ11B  : BLMO, TYPE="CSR" !CSR-based relative bunch length monitor
  IM11B  : IMON, TYPE="ICT" !toroid
  PH11B  : INST             !phase measurement RF cavity (#?#)
  TD11B  : INST             !insertable block (#?#)

! markers

  BC1cBEG : MARK
  BC1cEND : MARK

! ==============================================================================
! BEAMLINE
! ------------------------------------------------------------------------------

  SC1C00 : LINE=(XC1C00,YC1C00)
  SCCD11 : LINE=(XCCD11,YCCD11)
  SCCD12 : LINE=(XCCD12,YCCD12)
  SCC106 : LINE=(XCC106,YCC106)

  BC1i : LINE=(&
    BEGBC1B,&
    D1C00a,SC1C00,D1C00b,&
    Q1C01,BPM1C01,Q1C01,D1C01)

  BC1c0 : LINE=(BC1cBEG,&
    BCX11A,BCX11B,DC1o,&
    BCX12A,BCX12B,DC1i,&
    BCX13A,BCX13B,DC1o,&
    BCX14A,BCX14B,BC1cEND)

 !BC1c : LINE=(BC1cBEG,&
 !  BCX11A,BCX11B,DC1o,&
 !  BCX12A,BCX12B,DC1ia,BPMS11B,DC1ib,CEBC1,DC1ic,OTR11B,DC1id,&
 !  BCX13A,BCX13B,DC1o,&
 !  BCX14A,BCX14B,BC1cEND)

  BC1c : LINE=(BC1cBEG,&
    BCX11A,BCX11B,DC1oa,CQ11B,CQ11B,DC1ob,YCM12B,DC1oc,&
    BCX12A,BCX12B,DC1ia,BPMS11B,DC1ib,CEBC1,DC1ic,OTR11B,DC1id,&
    BCX13A,BCX13B,DC1od,CQ12B,CQ12B,DC1oe,&
    BCX14A,BCX14B,BC1cEND)

  BC1e : LINE=(DCD10a,BZ11B,DCD10b,&
    QCD11,BPMCD11,QCD11,DCD11a,SCCD11,DCD11b,&
    QCD12,BPMCD12,QCD12,DCD12a,SCCD12,DCD12b,&
    QCD13,BPMCD13,QCD13,DCD13,&
    QCD14,BPMCD14,QCD14,DCD14a,IM11B,DCD14b,&
    ENDBC1B,&
    SEQ02END)

  BC1 : LINE=(BC1i,BC1c,BC1e)

  COL1 : LINE=(&
    SEQ03BEG,&
    BEGCOL1,&
    DKYDG1a,DKYDG1b,DDC10,&
    QDC11,BPMDC11,QDC11,DDC11a,XCDC11,DDC11b,&
    QDC12,BPMDC12,QDC12,DDC12a,PH11B,TD11B,DDC12b,&
    QDC13,BPMDC13,QDC13,DDC13,CY11,DColl1c,&
    QC101,BPMC101,QC101,DColl1a,YCC101,DColl1b,CX11,DColl1c,&
    QC102,BPMC102,QC102,DColl1a,XCC102,DColl1b,CY12,DColl1c,&
    QC103,BPMC103,QC103,DColl1a,YCC103,DColl1b,CX12,DColl1c,&
    QC104,BPMC104,QC104,DDC14a,XCC104,DDC14b,&
    QC105,BPMC105,QC105,DDC15a,YCC105,DDC15b,&
    QC106,BPMC106,QC106,DDC16a,SCC106,DDC16b,&
    ENDCOL1)

  C1fodo : LINE=(&
    QFColl1,DColl1a,DColl1b,CY11,DColl1c,QDColl1,&
    QDColl1,DColl1a,DColl1b,CX11,DColl1c,QFColl1)

! ------------------------------------------------------------------------------

  RETURN