! *** OPTICS=LCLS2sc07AUG14 ***

! LCLS2sc linac extension: end of L3 to start of bypass dogleg

! ==============================================================================
! Modification History
! ------------------------------------------------------------------------------
! 07-AUG-2014, M. Woodley
!  * diagnostics complement per "Electron Beam Diagnostics Systems" PRD
!    (LCLSII-2.7-PR-0170)
!  * EXT FODO cell length increased from 38 m to 57 m ... phase advance per
!    cell reduced to 60 degrees
!  * use QW quadrupoles for FODO lattice ... last two EXT quadrupoles are QEs
!  * decorate device TYPE attributes to indicate non-baseline status
! ------------------------------------------------------------------------------
! 28-MAR-2014, M. Woodley
!  * element names changed to conform to nomenclature PRD
! ------------------------------------------------------------------------------

  LXfodo := 57.0            !FODO cell length (m)
! BETmax := 84.606981668362 !max FODO cell beta
! BETmin := 28.250054571793 !min FODO cell beta

! ==============================================================================
! QUAD
! ------------------------------------------------------------------------------

  KQXfodo := 0.141894975629  !60 degree FODO cells (GL < 16.5 kG @ 10 GeV)
! BminEXT := 32.932811780122
! BmaxEXT := 98.655253075642

  QFXfodo : QUAD, TYPE="4.63Q8.0", L=LQW/2, APER=rQW, K1= KQXfodo
  QDXfodo : QUAD, TYPE="4.63Q8.0", L=LQW/2, APER=rQW, K1=-KQXfodo

  KQX01 := -0.162986110985
  KQX02 :=  0.155045987651
  KQX03 := -KQXfodo
  KQX04 :=  KQXfodo
  KQX05 := -KQXfodo
  KQX06 :=  0.143561800093
  KQX07 := -0.140241374551
  KQX08 :=  0.869104098227
  KQX09 := -0.897813855446

  QX01 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX01
  QX02 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX02
  QX03 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX03
  QX04 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX04
  QX05 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX05
  QX06 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX06
  QX07 : QUAD, TYPE="4.63Q8.0",   L=LQW/2, APER=rQW, K1=KQX07
  QX08 : QUAD, TYPE="1.085Q4.31", L=LQE/2, APER=rQE, K1=KQX08
  QX09 : QUAD, TYPE="1.085Q4.31", L=LQE/2, APER=rQE, K1=KQX09

  COMMENT
    VALUE, Cb*10*KQXfodo*LQW
    VALUE, Cb*10*KQX01*LQW
    VALUE, Cb*10*KQX02*LQW
    VALUE, Cb*10*KQX06*LQW
    VALUE, Cb*10*KQX07*LQW
    VALUE, Cb*10*KQX08*LQE
    VALUE, Cb*10*KQX09*LQE
  ENDCOMMENT

! ==============================================================================
! DRIF
! ------------------------------------------------------------------------------

  LDXfodo := (LXfodo/2)-(QFXfodo[L]+QDXfodo[L]) !17.392

  DXfodo : DRIF, L=LDXfodo

  DX00  : DRIF, L=10.0
  DX01  : DRIF, L=LDXfodo
  DX02  : DRIF, L=LDXfodo
  DX03  : DRIF, L=LDXfodo
  DX04  : DRIF, L=LDXfodo
  DX05  : DRIF, L=LDXfodo
  DX06  : DRIF, L=LDXfodo
  DX07  : DRIF, L=31.100652
  DX08  : DRIF, L=8.5
  DX09  : DRIF, L=12.7-QX09[L]

  DX01a : DRIF, L=0.2
  DX01b : DRIF, L=DX01[L]-DX01a[L]
  DX02a : DRIF, L=0.2
  DX02b : DRIF, L=DX02[L]-DX02a[L]
  DX03a : DRIF, L=0.2
  DX03b : DRIF, L=DX03[L]-DX03a[L]
  DX04a : DRIF, L=0.2
  DX04b : DRIF, L=DX04[L]-DX04a[L]
  DX05a : DRIF, L=0.2
  DX05b : DRIF, L=DX05[L]-DX05a[L]
  DX06a : DRIF, L=0.2
  DX06c : DRIF, L=DX06[L]/2
  DX06b : DRIF, L=DX06[L]-DX06a[L]-DX06c[L]
  DX07a : DRIF, L=0.2
  DX07b : DRIF, L=DX07[L]-DX07a[L]
  DX08a : DRIF, L=0.2
  DX08c : DRIF, L=0.2
  DX08b : DRIF, L=DX08[L]-DX08a[L]-DX08c[L]
  DX09a : DRIF, L=0.2
  DX09b : DRIF, L=DX09[L]-DX09a[L]

! ==============================================================================
! BPMs
! ------------------------------------------------------------------------------

  BPMX01 : MONI, TYPE="10_um_res_R45"
  BPMX02 : MONI, TYPE="10_um_res_R45"
  BPMX03 : MONI, TYPE="10_um_res_R45"
  BPMX04 : MONI, TYPE="10_um_res_R45"
  BPMX05 : MONI, TYPE="10_um_res_R45"
  BPMX06 : MONI, TYPE="10_um_res_R45"
  BPMX07 : MONI, TYPE="10_um_res_R45"
  BPMX08 : MONI, TYPE="10_um_res_R45"

  RFBX06 : MONI, TYPE="@1,01_um_res"
  RFBX09 : MONI, TYPE="@1,01_um_res"

! ==============================================================================
! XCORs
! ------------------------------------------------------------------------------

  XCX02 : HKIC, TYPE="class-4"
  XCX04 : HKIC, TYPE="class-4"
  XCX06 : HKIC, TYPE="class-4"
  XCX08 : HKIC, TYPE="class-4"

! ==============================================================================
! YCORs
! ------------------------------------------------------------------------------

  YCX01 : VKIC, TYPE="class-4"
  YCX03 : VKIC, TYPE="class-4"
  YCX05 : VKIC, TYPE="class-4"
  YCX07 : VKIC, TYPE="class-4"
  YCX09 : VKIC, TYPE="class-4"

! ==============================================================================
! BEAMLINE
! ------------------------------------------------------------------------------

  Xfodo : LINE=(QDXfodo,DXfodo,QFXfodo,QFXfodo,DXfodo,QDXfodo)

  EXT0 : LINE=(BEGEXT,&
    DX00,&
    QX01,QX01,DX01,&
    QX02,QX02,DX02,&
    QX03,QX03,DX03,&
    QX04,QX04,DX04,&
    QX05,QX05,DX05,&
    QX06,QX06,DX06,&
    QX07,QX07,DX07,&
    QX08,QX08,DX08,&
    QX09,QX09,DX09,&
    ENDEXT)

  EXT : LINE=(&
    BEGEXT,&
    DX00,&
    QX01,BPMX01,QX01,DX01a,YCX01,DX01b,&
    QX02,BPMX02,QX02,DX02a,XCX02,DX02b,&
    QX03,BPMX03,QX03,DX03a,YCX03,DX03b,&
    QX04,BPMX04,QX04,DX04a,XCX04,DX04b,&
    QX05,BPMX05,QX05,DX05a,YCX05,DX05b,&
    QX06,BPMX06,QX06,DX06a,XCX06,DX06b,RFBX06,DX06c,&
    QX07,BPMX07,QX07,DX07a,YCX07,DX07b,&
    QX08,BPMX08,QX08,DX08a,XCX08,DX08b,RFBX09,DX08c,&
    QX09,QX09,DX09a,YCX09,DX09b,&
    ENDEXT,&
    SEQ03END)

! ------------------------------------------------------------------------------

  RETURN