! *** OPTICS=AD_ACCEL-17JAN24 ***

! ==============================================================================
! 07-JAN-2019, M. Woodley
!  * rename some LI21 correctors to avoid name conflicts with LCLS-II per
!    T. Maxwell
! ------------------------------------------------------------------------------
! 11-JAN-2007, P. Emma
!    Move QA11 a few mm as observed by alignment.
! 09-MAR-2006, P. Emma
!    Move SC11, SCA11, SCA12, and XC21202 and YC21203 per P. Stephens.
! 01-DEC-2005, P. Emma
!    Move XC21202 and YC21203 onto end of 21-1d.
! 29-NOV-2005, P. Emma
!    Add types for LCAV's.
! 09-NOV-2005, P. Emma
!    Use type-1 x/y corrector packages in L1-linac and relocate.
! 25-SEP-2005, P. Emma
!    Break L1 structure up to insert correctors at proper locations.
! ==============================================================================
! LCAVs
! ------------------------------------------------------------------------------
! the L1 linac consists of:   1 9.4  ft S-band sections @ 50% power
!                             1 9.4  ft S-band sections @ 25% power
!                             1 10   ft S-band sections @ 25% power
! ------------------------------------------------------------------------------

  dLb1    := 0.200+0.253432
  dLb2    := DLWL9-dLb1
  K21_1b1 : LCAV, FREQ=SbandF, L=dLb1, DELTAE=P50*gradL1*dLb1, PHI0=PhiL1, &
                  TYPE="9.4ft"
  K21_1b2 : LCAV, FREQ=SbandF, L=dLb2, DELTAE=P50*gradL1*dLb2, PHI0=PhiL1, &
                  TYPE="9.4ft"
  dLc1    := 0.200+0.2534458
  dLc2    := DLWL9-dLc1
  K21_1c1 : LCAV, FREQ=SbandF, L=dLc1,  DELTAE=P25*gradL1*dLc1, PHI0=PhiL1, &
                  TYPE="9.4ft"
  K21_1c2 : LCAV, FREQ=SbandF, L=dLc2,  DELTAE=P25*gradL1*dLc2, PHI0=PhiL1, &
                  TYPE="9.4ft"
  dLd1    := 0.200+0.1693348
  dLd3    := 0.300+0.167527-0.1799554
  dLd4    := 0.200+0.1799554
  dLd2    := DLWL10-dLd1-dLd3-dLd4
  K21_1d1 : LCAV, FREQ=SbandF, L=dLd1, DELTAE=P25*gradL1*dLd1, PHI0=PhiL1, &
                  TYPE="10ft"
  K21_1d2 : LCAV, FREQ=SbandF, L=dLd2, DELTAE=P25*gradL1*dLd2, PHI0=PhiL1, &
                  TYPE="10ft"
  K21_1d3 : LCAV, FREQ=SbandF, L=dLd3, DELTAE=P25*gradL1*dLd3, PHI0=PhiL1, &
                  TYPE="10ft"
  K21_1d4 : LCAV, FREQ=SbandF, L=dLd4, DELTAE=P25*gradL1*dLd4, PHI0=PhiL1, &
                  TYPE="10ft"

! define unsplit LCAVs for BMAD ... not used by MAD

  K21_1b : LCAV, FREQ=SbandF, L=DLWL9,  DELTAE=P50*gradL1*DLWL9,  PHI0=PhiL1, &
                 TYPE="9.4ft"
  K21_1c : LCAV, FREQ=SbandF, L=DLWL9,  DELTAE=P25*gradL1*DLWL9,  PHI0=PhiL1, &
                 TYPE="9.4ft"
  K21_1d : LCAV, FREQ=SbandF, L=DLWL10, DELTAE=P25*gradL1*DLWL10, PHI0=PhiL1, &
                 TYPE="10ft"

! ==============================================================================
! BEAMLINEs
! ------------------------------------------------------------------------------

  K21_1b_full : LINE=(K21_1b1,XC21101,YC21102,K21_1b2)
  K21_1c_full : LINE=(K21_1c1,XC21135,YC21136,K21_1c2)
  K21_1d_full : LINE=(K21_1d1,XC21165,YC21166,K21_1d2,YC21174,&
                      K21_1d3,XC21175,K21_1d4)

  QA11_full : LINE=(QA11,BPMA11,QA11)
  QA12_full : LINE=(QA12,BPMA12,QA12)

  L1 : LINE=(BEGL1,ZLIN01,&
    K21_1b_full,DAQA1,QA11_full,DAQA2,&
    K21_1c_full,DAQA3,QA12_full,DAQA4,&
    K21_1d_full,&
    ENDL1)

! ==============================================================================

  RETURN