Go to the previous, next section.

Minibuffers

A minibuffer is a special buffer that Emacs commands use to read arguments more complicated than the single numeric prefix argument. These arguments include file names, buffer names, and command names (as in M-x). The minibuffer is displayed on the bottom line of the screen, in the same place as the echo area, but only while it is in use for reading an argument.

Introduction to Minibuffers

In most ways, a minibuffer is a normal Emacs buffer. Most operations within a buffer, such as editing commands, work normally in a minibuffer. However, many operations for managing buffers do not apply to minibuffers. The name of a minibuffer always has the form ` *Minibuf-number', and it cannot be changed. Minibuffers are displayed only in special windows used only for minibuffers; these windows always appear at the bottom of a frame. (Sometime frames have no minibuffer window, and sometimes a special kind of frame contains nothing but a minibuffer window; see section Minibuffers and Frames.)

The minibuffers window is normally a single line; you can resize it temporarily with the window sizing commands, but reverts to its normal size when the minibuffer is exited.

A recursive minibuffer may be created when there is an active minibuffer and a command is invoked that requires input from a minibuffer. The first minibuffer is named ` *Minibuf-0*'. Recursive minibuffers are named by incrementing the number at the end of the name. (The names begin with a space so that they won't show up in normal buffer lists.) Of several recursive minibuffers, the innermost (or most recently entered) is the active minibuffer. We usually call this "the" minibuffer. You can permit or forbid recursive minibuffers by setting the variable enable-recursive-minibuffers or by putting properties of that name on command symbols (see section Minibuffer Miscellany).

Like other buffers, a minibuffer may use any of several local keymaps (see section Keymaps); these contain various exit commands and in some cases completion commands. See section Completion.

Reading Text Strings with the Minibuffer

The minibuffer is usually used to read text which is returned as a string, but can also be used to read a Lisp object in textual form. The most basic primitive for minibuffer input is read-from-minibuffer.

Function: read-from-minibuffer prompt-string &optional initial keymap read hist

This function is the most general way to get input through the minibuffer. By default, it accepts arbitrary text and returns it as a string; however, if read is non-nil, then it uses read to convert the text into a Lisp object (see section Input Functions).

The first thing this function does is to activate a minibuffer and display it with prompt-string as the prompt. This value must be a string.

Then, if initial is a string; its contents are inserted into the minibuffer as initial contents. The text thus inserted is treated as if the user had inserted it; the user can alter it with Emacs editing commands.

The value of initial may also be a cons cell of the form (string . position). This means to insert string in the minibuffer but put the cursor position characters from the beginning, rather than at the end.

If keymap is non-nil, that keymap is the local keymap to use while reading. If keymap is omitted or nil, the value of minibuffer-local-map is used as the keymap. Specifying a keymap is the most important way to customize minibuffer input for various applications including completion.

The argument hist specifies which history list variable to use for saving the input and for history commands used in the minibuffer. It defaults to minibuffer-history. See section Minibuffer History.

When the user types a command to exit the minibuffer, the current minibuffer contents are usually made into a string which becomes the value of read-from-minibuffer. However, if read is non-nil, read-from-minibuffer converts the result to a Lisp object, and returns that object, unevaluated.

Suppose, for example, you are writing a search command and want to record the last search string and provide it as a default for the next search. Suppose that the previous search string is stored in the variable last-search-string. Here is how you can read a search string while providing the previous string as initial input to be edited:

(read-from-minibuffer "Find string: " last-search-string)

Assuming the value of last-search-string is `No', and the user wants to search for `Nope', the interaction looks like this:

(setq last-search-string "No")

(read-from-minibuffer "Find string: " last-search-string)
---------- Buffer: Minibuffer ----------
Find string: No-!-
---------- Buffer: Minibuffer ----------
;; The user now types pe RET:
     => "Nope"

This technique is no longer preferred for most applications; it is usually better to use a history list.

Function: read-string prompt &optional initial

This function reads a string from the minibuffer and returns it. The arguments prompt and initial are used as in read-from-minibuffer.

This is a simplified interface to the read-from-minibuffer function:

(read-string prompt initial)
==
(read-from-minibuffer prompt initial nil nil)

Variable: minibuffer-local-map

This is the default local keymap for reading from the minibuffer. It is the keymap used by the minibuffer for local bindings in the function read-string. By default, it makes the following bindings:

LFD
exit-minibuffer

RET
exit-minibuffer

C-g
abort-recursive-edit

M-n and M-p
next-history-element and previous-history-element

M-r
next-matching-history-element

M-s
previous-matching-history-element

Function: read-no-blanks-input prompt &optional initial

This function reads a string from the minibuffer, but does not allow whitespace characters as part of the input: instead, those characters terminate the input. The arguments prompt and initial are used as in read-from-minibuffer.

This is a simplified interface to the read-from-minibuffer function, and passes the value of the minibuffer-local-ns-map keymap as the keymap argument for that function. Since the keymap minibuffer-local-ns-map does not rebind C-q, it is possible to put a space into the string, by quoting it.

(read-no-blanks-input prompt initial)
==
(read-from-minibuffer prompt initial minibuffer-local-ns-map)

Variable: minibuffer-local-ns-map

This built-in variable is the keymap used as the minibuffer local keymap in the function read-no-blanks-input. By default, it makes the following bindings:

LFD
exit-minibuffer

SPC
exit-minibuffer

TAB
exit-minibuffer

RET
exit-minibuffer

C-g
abort-recursive-edit

?
self-insert-and-exit

M-n and M-p
next-history-element and previous-history-element

M-r
next-matching-history-element

M-s
previous-matching-history-element

Reading Lisp Objects with the Minibuffer

This section describes functions for reading Lisp objects with the minibuffer.

Function: read-minibuffer prompt &optional initial

This function reads a Lisp object in the minibuffer and returns it, without evaluating it. The arguments prompt and initial are used as in read-from-minibuffer; in particular, initial must be a string or nil.

This is a simplified interface to the read-from-minibuffer function:

(read-minibuffer prompt initial)
==
(read-from-minibuffer prompt initial nil t)

Here is an example in which we supply the string "(testing)" as initial input:

(read-minibuffer
 "Enter an expression: " (format "%s" '(testing)))

;; Here is how the minibuffer is displayed:

---------- Buffer: Minibuffer ----------
Enter an expression: (testing)-!-
---------- Buffer: Minibuffer ----------

The user can type RET immediately to use the initial input as a default, or can edit the input.

Function: eval-minibuffer prompt &optional initial

This function reads a Lisp expression in the minibuffer, evaluates it, then returns the result. The arguments prompt and initial are used as in read-from-minibuffer.

This function simply evaluates the result of a call to read-minibuffer:

(eval-minibuffer prompt initial)
==
(eval (read-minibuffer prompt initial))

Function: edit-and-eval-command prompt form

This function reads a Lisp expression in the minibuffer, and then evaluates it. The difference between this command and eval-minibuffer is that here the initial form is not optional and it is treated as a Lisp object to be converted to printed representation rather than as a string of text. It is printed with prin1, so if it is a string, double-quote characters (`"') appear in the initial text. See section Output Functions.

The first thing edit-and-eval-command does is to activate the minibuffer with prompt as the prompt. Then it inserts the printed representation of form in the minibuffer, and lets the user edit. When the user exits the minibuffer, the edited text is read with read and then evaluated. The resulting value becomes the value of edit-and-eval-command.

In the following example, we offer the user an expression with initial text which is a valid form already:

(edit-and-eval-command "Please edit: " '(forward-word 1))

;; After evaluating the preceding expression, 
;;   the following appears in the minibuffer:

---------- Buffer: Minibuffer ----------
Please edit: (forward-word 1)-!-
---------- Buffer: Minibuffer ----------

Typing RET right away would exit the minibuffer and evaluate the expression, thus moving point forward one word. edit-and-eval-command returns nil in this example.

Minibuffer History

A minibuffer history list records previous minibuffer inputs so the user can reuse them conveniently. There are many separate history lists which contain different kinds of inputs. The Lisp programmer's job is to specify the right history list for each use of the minibuffer.

The basic minibuffer input functions read-from-minibuffer and completing-read both accept an optional argument named hist which is how you specify the history list. Here are the possible values:

variable
If you specify a variable (a symbol), that variable is the history list.

(variable . startpos)
If you specify a cons cell of this form, then variable is the history list variable, and startpos specifies the initial history position (an integer, counting from zero which specifies the most recent element of the history).

If you specify startpos, then you should also specify that element of the history as initial, for consistency.

If you don't specify hist, then the default history list minibuffer-history is used. For other standard history lists, see below. You can also create your own history list variable; just initialize it to nil before the first use. The value of the history list variable is a list of strings, most recent first.

Both read-from-minibuffer and completing-read add new elements to the history list automatically, and provide commands to allow the user to reuse items on the list. The only thing your program needs to do to use a history list is to initialize it and to pass its name to the input functions when you wish. But it is safe to modify the list by hand when the minibuffer input functions are not using it.

Variable: minibuffer-history

The default history list for minibuffer history input.

Variable: query-replace-history

A history list for arguments to query-replace (and similar arguments to other commands).

Variable: file-name-history

A history list for file name arguments.

Completion

Completion is a feature that fills in the rest of a name starting from an abbreviation for it. Completion works by comparing the user's input against a list of valid names and determining how much of the name is determined uniquely by what the user has typed.

For example, when you type C-x b (switch-to-buffer) and then type the first few letters of the name of the buffer to which you wish to switch, and then type TAB (minibuffer-complete), Emacs extends the name as far as it can. Standard Emacs commands offer completion for names of symbols, files, buffers, and processes; with the functions in this section, you can implement completion for other kinds of names.

The try-completion function is the basic primitive for completion: it returns the longest determined completion of a given initial string, with a given set of strings to match against.

The function completing-read provides a higher-level interface for completion. A call to completing-read specifies how to determine the list of valid names. The function then activates the minibuffer with a local keymap that binds a few keys to commands useful for completion. Other functions provide convenient simple interfaces for reading certain kinds of names with completion.

Basic Completion Functions

Function: try-completion string collection &optional predicate

This function returns the longest common substring of all possible completions of string in collection. The value of collection must be an alist, an obarray, or a function which implements a virtual set of strings.

If collection is an alist (see section Association Lists), completion compares the CAR of each cons cell in it against string; if the beginning of the CAR equals string, the cons cell matches. If no cons cells match, try-completion returns nil. If only one cons cell matches, and the match is exact, then try-completion returns t. Otherwise, the value is the longest initial sequence common to all the matching strings in the alist.

If collection is an obarray (see section Creating and Interning Symbols), the names of all symbols in the obarray form the space of possible completions. They are tested and used just like the CARs of the elements of an association list. (The global variable obarray holds an obarray containing the names of all interned Lisp symbols.)

Note that the only valid way to make a new obarray is to create it empty and then add symbols to it one by one using intern. Also, you cannot intern a given symbol in more than one obarray.

If the argument predicate is non-nil, then it must be a function of one argument. It is used to test each possible match, and the match is accepted only if predicate returns non-nil. The argument given to predicate is either a cons cell from the alist (the CAR of which is a string) or else it is a symbol (not a symbol name) from the obarray.

It is also possible to use a function symbol as collection. Then the function is solely responsible for performing completion; try-completion returns whatever this function returns. The function is called with three arguments: string, predicate and nil. (The reason for the third argument is so that the same function can be used in all-completions and do the appropriate thing in either case.) See section Programmed Completion.

In the first of the following examples, the string `foo' is matched by three of the alist CARs. All of the matches begin with the characters `fooba', so that is the result. In the second example, there is only one possible match, and it is exact, so the value is t.

(try-completion 
 "foo"
 '(("foobar1" 1) ("barfoo" 2) ("foobaz" 3) ("foobar2" 4)))
     => "fooba"

(try-completion "foo" '(("barfoo" 2) ("foo" 3)))
     => t

In the following example, numerous symbols begin with the characters `forw', and all of them begin with the word `forward'. In most of the symbols, this is followed with a `-', but not in all, so no more than `forward' can be completed.

(try-completion "forw" obarray)
     => "forward"

Finally, in the following example, only two of the three possible matches pass the predicate test (the string `foobaz' is too short). Both of those begin with the string `foobar'.

(defun test (s) 
  (> (length (car s)) 6))
     => test
(try-completion 
 "foo"
 '(("foobar1" 1) ("barfoo" 2) ("foobaz" 3) ("foobar2" 4)) 
     'test)
     => "foobar"

Function: all-completions string collection &optional predicate

This function returns a list of all possible completions, instead of the longest substring they share. The parameters to this function are the same as to try-completion.

If collection is a function, it is called with three arguments: string, predicate and t, and all-completions returns whatever the function returns. See section Programmed Completion.

Here is an example, using the function test shown in the example for try-completion:

(defun test (s) 
  (> (length (car s)) 6))
     => test

(all-completions  
 "foo"
 '(("foobar1" 1) ("barfoo" 2) ("foobaz" 3) ("foobar2" 4))
 (function test))
     => ("foobar1" "foobar2")

Variable: completion-ignore-case

If the value of this variable is non-nil, Emacs does not consider case significant in completion.

The two functions try-completion and all-completions have nothing in themselves to do with minibuffers. However, completion is most often used there, which is why it is described in this chapter.

Programmed Completion

Sometimes it is not possible to create an alist or an obarray containing all the intended possible completions. In such a case, you can supply your own function to compute the completion of a given string. This is called programmed completion.

To use this feature, pass a symbol with a function definition as the collection argument to completing-read. This command arranges to pass the function along to try-completion and all-completions, which will then let your function do all the work.

The completion function should accept three arguments:

There are three flag values for three operations:

It would be consistent and clean for completion functions to allow lambda expressions (lists which are functions) as well as function symbols as collection, but this is impossible. Lists as completion tables are already assigned another meaning--as alists. It would be unreliable to fail to handle an alist normally because it is also a possible function. So you must arrange for any function you wish to use for completion to be encapsulated in a symbol.

Emacs uses programmed completion when completing file names. See section File Name Completion.

Completion and the Minibuffer

This section describes the basic interface for reading from the minibuffer with completion.

Function: completing-read prompt collection &optional predicate require-match initial hist

This function reads a string in the minibuffer, assisting the user by providing completion. It activates the minibuffer with prompt prompt, which must be a string. If initial is non-nil, completing-read inserts it into the minibuffer as part of the input. Then it allows the user to edit the input, providing several commands to attempt completion.

The actual completion is done by passing collection and predicate to the function try-completion. This happens in certain commands bound in the local keymaps used for completion.

If require-match is t, the user is not allowed to exit unless the input completes to an element of collection. If require-match is neither nil nor t, then completing-read does not exit unless the input typed is itself an element of collection. To accomplish this, completing-read calls read-minibuffer. It uses the value of minibuffer-local-completion-map as the keymap if require-match is nil, and uses minibuffer-local-must-match-map if require-match is non-nil.

The argument hist specifies which history list variable to use for saving the input and for minibuffer history commands. It defaults to minibuffer-history. See section Minibuffer History.

Case is ignored when comparing the input against the possible matches if the built-in variable completion-ignore-case is non-nil. See section Basic Completion Functions.

For example:

(completing-read
 "Complete a foo: "
 '(("foobar1" 1) ("barfoo" 2) ("foobaz" 3) ("foobar2" 4))
 nil t "fo")

;; After evaluating the preceding expression, 
;;   the following appears in the minibuffer:

---------- Buffer: Minibuffer ----------
Complete a foo: fo-!-
---------- Buffer: Minibuffer ----------

If the user then types DEL DEL b RET, completing-read returns barfoo.

The completing-read function binds three variables to pass information to the commands which actually do completion. Here they are:

minibuffer-completion-table
This variable is bound to the collection argument. It is passed to the try-completion function.

minibuffer-completion-predicate
This variable is bound to the predicate argument. It is passed to the try-completion function.

minibuffer-completion-confirm
This variable is bound to the require-match argument. It is used in the minibuffer-complete-and-exit function.

Minibuffer Commands That Do Completion

This section describes the keymaps, commands and user options used in the minibuffer to do completion.

Variable: minibuffer-local-completion-map

completing-read uses this value as the local keymap when an exact match of one of the completions is not required. By default, this keymap makes the following bindings:

?
minibuffer-completion-help

SPC
minibuffer-complete-word

TAB
minibuffer-complete

with other characters bound as in minibuffer-local-map.

Variable: minibuffer-local-must-match-map

completing-read uses this value as the local keymap when an exact match of one of the completions is required. Therefore, no keys are bound to exit-minibuffer, the command which exits the minibuffer unconditionally. By default, this keymap makes the following bindings:

?
minibuffer-completion-help

SPC
minibuffer-complete-word

TAB
minibuffer-complete

LFD
minibuffer-complete-and-exit

RET
minibuffer-complete-and-exit

with other characters bound as in minibuffer-local-map.

Variable: minibuffer-completion-table

The value of this variable is the alist or obarray used for completion in the minibuffer. This is the global variable that contains what completing-read passes to try-completion. It is used by all the minibuffer completion functions, such as minibuffer-complete-word.

Variable: minibuffer-completion-predicate

This variable's value is the predicate that completing-read passes to try-completion. The variable is also used by the other minibuffer completion functions.

Command: minibuffer-complete-word

This function completes the minibuffer contents by at most a single word. Even if the minibuffer contents have only one completion, minibuffer-complete-word does not add any characters beyond the first character that is not a word constituent. See section Syntax Tables.

Command: minibuffer-complete

This function completes the minibuffer contents as far as possible.

Command: minibuffer-complete-and-exit

This function completes the minibuffer contents, and exits if confirmation is not required, i.e., if minibuffer-completion-confirm is non-nil. If confirmation is required, it is given by repeating this command immediately.

Variable: minibuffer-completion-confirm

When the value of this variable is non-nil, Emacs asks for confirmation of a completion before exiting the minibuffer. The function minibuffer-complete-and-exit checks the value of this variable before it exits.

Command: minibuffer-completion-help

This function creates a list of the possible completions of the current minibuffer contents. It works by calling all-completions using the value of the variable minibuffer-completion-table as the collection argument, and the value of minibuffer-completion-predicate as the predicate argument. The list of completions is displayed as text in a buffer named `*Completions*'.

Function: display-completion-list completions

This function displays completions to the stream in standard-output, usually a buffer. (See section Reading and Printing Lisp Objects, for more information about streams.) The argument completions is normally a list of completions just returned by all-completions, but it does not have to be. Each element may be a symbol or a string, either of which is simply printed, or a list of two strings, which is printed as if the strings were concatenated.

This function is called by minibuffer-completion-help. The most common way to use it is together with with-output-to-temp-buffer, like this:

(with-output-to-temp-buffer " *Completions*"
  (display-completion-list
    (all-completions (buffer-string) my-alist)))

User Option: completion-auto-help

If this variable is non-nil, the completion commands automatically display a list of possible completions whenever nothing can be completed because the next character is not uniquely determined.

High-Level Completion Functions

This section describes the higher-level convenient functions for reading certain sorts of names with completion.

Function: read-buffer prompt &optional default existing

This function reads the name of a buffer and returns it as a string. The argument default is the default name to use, the value to return if the user exits with an empty minibuffer. If non-nil, it should be a string. It is mentioned in the prompt, but is not inserted in the minibuffer as initial input.

If existing is non-nil, then the name specified must be that of an existing buffer. The usual commands to exit the minibuffer do not exit if the text is not valid, and RET does completion to attempt to find a valid name. (However, default is not checked for this; it is returned, whatever it is, if the user exits with the minibuffer empty.)

In the following example, the user enters `minibuffer.t', and then types RET. The argument existing is t, and the only buffer name starting with the given input is `minibuffer.texi', so that name is the value.

(read-buffer "Buffer name? " "foo" t)

;; After evaluating the preceding expression, 
;;   the following prompt appears,
;;   with an empty minibuffer:

---------- Buffer: Minibuffer ----------
Buffer name? (default foo) -!-
---------- Buffer: Minibuffer ----------

;; The user types minibuffer.t RET.

     => "minibuffer.texi"

Function: read-command prompt

This function reads the name of a command and returns it as a Lisp symbol. The argument prompt is used as in read-from-minibuffer. Recall that a command is anything for which commandp returns t, and a command name is a symbol for which commandp returns t. See section Interactive Call.

(read-command "Command name? ")

;; After evaluating the preceding expression, 
;;   the following appears in the minibuffer:

---------- Buffer: Minibuffer ---------- 
Command name?  
---------- Buffer: Minibuffer ----------

If the user types forward-c RET, then this function returns forward-char.

The read-command function is a simplified interface to the completing-read function. It uses the commandp predicate to allow only commands to be entered, and it uses the variable obarray so as to be able to complete all extant Lisp symbols:

(read-command prompt)
==
(intern (completing-read prompt obarray 'commandp t nil))

Function: read-variable prompt

This function reads the name of a user variable and returns it as a symbol.

(read-variable "Variable name? ")

;; After evaluating the preceding expression, 
;;   the following prompt appears, 
;;   with an empty minibuffer:

---------- Buffer: Minibuffer ----------
Variable name? -!-
---------- Buffer: Minibuffer ----------

If the user then types fill-p RET, read-variable will return fill-prefix.

This function is similar to read-command, but uses the predicate user-variable-p instead of commandp:

(read-variable prompt)
==
(intern
 (completing-read prompt obarray 'user-variable-p t nil))

Reading File Names

Here is another high-level completion function, designed for reading a file name. It provides special features including automatic insertion of the default directory.

Function: read-file-name prompt &optional directory default existing initial

This function reads a file name in the minibuffer, prompting with prompt and providing completion. If default is non-nil, then the function returns default if the user just types RET.

If existing is non-nil, then the name must refer to an existing file; then RET performs completion to make the name valid if possible, and then refuses to exit if it is not valid. If the value of existing is neither nil nor t, then RET also requires confirmation after completion.

The argument directory specifies the directory to use for completion of relative file names. Usually it is inserted in the minibuffer as initial input as well. It defaults to the current buffer's default directory.

If you specify initial, that is an initial file name to insert in the buffer along with directory. In this case, point goes after directory, before initial. The default for initial is nil---don't insert any file name. To see what initial does, try the command C-x C-v.

Here is an example:

(read-file-name "The file is ")

;; After evaluating the preceding expression, 
;;   the following appears in the minibuffer:

---------- Buffer: Minibuffer ----------
The file is /gp/gnu/elisp/-!-
---------- Buffer: Minibuffer ----------

Typing manual TAB results in the following:

---------- Buffer: Minibuffer ----------
The file is /gp/gnu/elisp/manual.texi-!-
---------- Buffer: Minibuffer ----------

If the user types RET, read-file-name returns the string "/gp/gnu/elisp/manual.texi".

User Option: insert-default-directory

This variable is used by read-file-name. Its value controls whether read-file-name starts by placing the name of the default directory in the minibuffer, plus the initial file name if any. If the value of this variable is nil, then read-file-name does not place any initial input in the minibuffer. In that case, the default directory is still used for completion of relative file names, but is not displayed.

For example:

;; Here the minibuffer starts out containing the default directory.

(let ((insert-default-directory t))
  (read-file-name "The file is "))

---------- Buffer: Minibuffer ----------
The file is ~lewis/manual/-!-
---------- Buffer: Minibuffer ----------

;; Here the minibuffer is empty and only the prompt
;;   appears on its line.

(let ((insert-default-directory nil))
  (read-file-name "The file is "))

---------- Buffer: Minibuffer ----------
The file is -!-
---------- Buffer: Minibuffer ----------

Lisp Symbol Completion

If you type a part of a symbol, and then type M-TAB (lisp-complete-symbol), this command attempts to fill in as much more of the symbol name as it can. Not only does this save typing, but it can help you with the name of a symbol that you have partially forgotten.

Command: lisp-complete-symbol

This function performs completion on the symbol name preceding point. The name is completed against the symbols in the global variable obarray, and characters from the completion are inserted into the buffer, making the name longer. If there is more than one completion, a list of all possible completions is placed in the `*Help*' buffer. The bell rings if there is no possible completion in obarray.

If an open parenthesis immediately precedes the name, only symbols with function definitions are considered. (By reducing the number of alternatives, this may succeed in completing more characters.) Otherwise, symbols with either a function definition, a value, or at least one property are considered.

lisp-complete-symbol returns t if the symbol had an exact, and unique, match; otherwise, it returns nil.

In the following example, the user has already inserted `(forwa' into the buffer `foo.el'. The command lisp-complete-symbol then completes the name to `(forward-'.

---------- Buffer: foo.el ----------
(forwa-!-
---------- Buffer: foo.el ----------

(lisp-complete-symbol)
     => nil

---------- Buffer: foo.el ----------
(forward--!-
---------- Buffer: foo.el ----------

Yes-or-No Queries

This section describes functions used to ask the user a yes-or-no question. The function y-or-n-p can be answered with a single character; it is useful for questions where an inadvertent wrong answer will not have serious consequences. yes-or-no-p is suitable for more momentous questions, since it requires three or four characters to answer.

Strictly speaking, yes-or-no-p uses the minibuffer and y-or-n-p does not; but it seems best to describe them together.

Function: y-or-n-p prompt

This function asks the user a question, expecting input in the echo area. It returns t if the user types y, nil if the user types n. This function also accepts SPC to mean yes and DEL to mean no. It accepts C-] to mean "quit", like C-g, because the question might look like a minibuffer and for that reason the user might try to use C-] to get out. The answer is a single character, with no RET needed to terminate it. Upper and lower case are equivalent.

"Asking the question" means printing prompt in the echo area, followed by the string `(y or n) '. If the input is not one of the expected answers (y, n, SPC, DEL, or something that quits), the function responds `Please answer y or n.', and repeats the request.

This function does not actually use the minibuffer, since it does not allow editing of the answer. It actually uses the echo area (see section The Echo Area), which uses the same screen space as the minibuffer. The cursor moves to the echo area while the question is being asked.

The meanings of answers, even `y' and `n', are not hardwired. They are controlled by the keymap query-replace-map. See section Replacement.

In the following example, the user first types q, which is invalid. At the next prompt the user types n.

(y-or-n-p "Do you need a lift? ")

;; After evaluating the preceding expression, 
;;   the following prompt appears in the echo area:

---------- Echo area ----------
Do you need a lift? (y or n) 
---------- Echo area ----------

;; If the user then types q, the following appears:

---------- Echo area ----------
Please answer y or n.  Do you need a lift? (y or n) 
---------- Echo area ----------

;; When the user types a valid answer,
;;   it is displayed after the question:

---------- Echo area ----------
Do you need a lift? (y or n) y
---------- Echo area ----------

Note that we show successive lines of echo area messages here. Only one actually appears on the screen at a time.

Function: yes-or-no-p prompt

This function asks the user a question, expecting input in minibuffer. It returns t if the user enters `yes', nil if the user types `no'. The user must type RET to finalize the response. Upper and lower case are equivalent.

yes-or-no-p starts by displaying prompt in the echo area, followed by `(yes or no) '. The user must type one of the expected responses; otherwise, the function responds `Please answer yes or no.', waits about two seconds and repeats the request.

yes-or-no-p requires more work from the user than y-or-n-p and is appropriate for more crucial decisions.

Here is an example:

(yes-or-no-p "Do you really want to remove everything? ")

;; After evaluating the preceding expression, 
;;   the following prompt appears, 
;;   with an empty minibuffer:

---------- Buffer: minibuffer ----------
Do you really want to remove everything? (yes or no) 
---------- Buffer: minibuffer ----------

If the user first types y RET, which is invalid because this function demands the entire word `yes', it responds by displaying these prompts, with a brief pause between them:

---------- Buffer: minibuffer ----------
Please answer yes or no.
Do you really want to remove everything? (yes or no)
---------- Buffer: minibuffer ----------

Asking Multiple Y-or-N Queries

Function: map-y-or-n-p prompter actor list &optional help action-alist

This function, new in Emacs 19, asks the user a series of questions, reading a single-character answer in the echo area for each one.

The value of list specifies what varies from question to question within the series. It should be either a list of objects or a generator function. If it is a function, it should expect no arguments, and should return either the next object or nil meaning there are no more questions.

The argument prompter specifies how to ask each question. If prompter is a string, the question text is computed like this:

(format prompter object)

where object is the next object to ask about (as obtained from list).

If not a string, prompter should be a function of one argument (the next object to ask about) and should return the question text.

The argument actor says how to act on the answers that the user gives. It should be a function of one argument, and it is called with each object that the user says yes for. Its argument is always an object obtained from list.

If the argument help is given, it should be a list of this form:

(singular plural action)

where singular is a string containing a singular noun that describes the objects conceptually being acted on, plural is the corresponding plural noun, and action is a transitive verb describing what actor does.

If you don't specify help, the default is ("object" "objects" "act on").

Each time a question is asked, the user may enter y, Y, or SPC to act on that object; n, N, or DEL to skip that object; ! to act on all following objects; ESC or q to exit (skip all following objects); . (period) to act on the current object and then exit; or C-h to get help. These are the same answers that query-replace accepts. The keymap query-replace-map defines their meaning for map-y-or-n-p as well as for query-replace; see section Replacement.

You can use action-alist to specify additional possible answers and what they mean. It is an alist of elements of the form (char function help), each of which defines one additional answer. In this element, char is a character (the answer); function is a function of one argument (an object from list); help is a string.

When the user responds with char, map-y-or-n-p calls function. If it returns non-nil, the object is considered "acted upon", and map-y-or-n-p advances to the next object in list. If it returns nil, the prompt is repeated for the same object.

The return value of map-y-or-n-p is the number of objects acted on.

Minibuffer Miscellany

This section describes some basic functions and variables related to minibuffers.

Command: exit-minibuffer

This command exits the active minibuffer. It is normally bound to keys in minibuffer local keymaps.

Command: self-insert-and-exit

This command exits the active minibuffer after inserting the last character typed on the keyboard (found in last-command-char; see section Information from the Command Loop).

Command: previous-history-element n

This command replaces the minibuffer contents with the value of the nth previous (older) history element.

Command: next-history-element n

This command replaces the minibuffer contents with the value of the nth more recent history element.

Command: previous-matching-history-element pattern

This command replaces the minibuffer contents with the value of the previous (older) history element that matches pattern. At the time of printing, we have not made a final decision about how to get the pattern interactively or how to match it against history elements.

Command: next-matching-history-element pattern

This command replaces the minibuffer contents with the value of the next (newer) history element that matches pattern.

Variable: minibuffer-setup-hook

This is a normal hook that is run whenever the minibuffer is entered.

Variable: minibuffer-help-form

The current value of this variable is used to rebind help-form locally inside the minibuffer (see section Help Functions).

Function: minibuffer-window &optional frame

This function returns the window that is used for the minibuffer. In Emacs 18, there is one and only one minibuffer window; this window always exists and cannot be deleted. In Emacs 19, each frame can have its own minibuffer, and this function returns the minibuffer window used for frame frame (which defaults to the currently selected frame).

Function: window-minibuffer-p window

This function returns non-nil if window is a minibuffer window.

It is not correct to determine whether a given window is a minibuffer by comparing it with the result of (minibuffer-window), because there can be more than one minibuffer window there is more than one frame.

Function: minibuffer-window-active-p window

This function returns non-nil if window, assumed to be a minibuffer window, is currently active.

Variable: minibuffer-scroll-window

If the value of this variable is non-nil, it should be a window object. When the function scroll-other-window is called in the minibuffer, it scrolls this window.

Finally, some functions and variables deal with recursive minibuffers (see section Recursive Editing):

Function: minibuffer-depth

This function returns the current depth of activations of the minibuffer, a nonnegative integer. If no minibuffers are active, it returns zero.

User Option: enable-recursive-minibuffers

If this variable is non-nil, you can invoke commands (such as find-file) which use minibuffers even while in the minibuffer window. Such invocation produces a recursive editing level for a new minibuffer. The outer-level minibuffer is invisible while you are editing the inner one.

This variable only affects invoking the minibuffer while the minibuffer window is selected. If you switch windows while in the minibuffer, you can always invoke minibuffer commands while some other window is selected.

If a command name has a property enable-recursive-minibuffers which is non-nil, then the command can use the minibuffer to read arguments even if it is invoked from the minibuffer. The minibuffer command next-matching-history-element (normally bound to M-s in the minibuffer) uses this feature.

Go to the previous, next section.